Acquisire il codice HTML di una pagina web

Da Gambas-it.org - Wikipedia.

L'acquisizione del codice HTML di una pagina web può essere effettuata mediante le modalità appresso descritte.

Uso delle sole risorse di Gambas

Vi sono due modalità che prevedono l'uso delle sole risorse di Gambas.

Uso dell'oggetto WebView

Per poter utilizzare l'oggetto WebView, bisognerà attivare anche il Componente gb.qui.qt.webkit o il Componente gb.qt5.webkit.
Verrà innanzitutto caricata la pagina web con la Proprietà ".Url" dell'Oggetto WebView. Successvamente si acquisirà il codice html di detta pagina mediante la Proprietà ".HTML": 

Public Sub Form_Open()  

 WebView1.Url = "https://www.pagina_web_da_caricare"  

End


Public Sub WebView1_Finish()  ' Quando la pagina web è stata completamente caricata dalla "WebView", viene sollevato questo evento:
 
 Dim s As String  
  
' Carica nella variabile di tipo stringa il codice HTML della pagina web:
 s = WebView1.GetHtml()

' Salva il codice html, ottenuto, in apposito file:
 File.Save("/tmp/codice_html.html", s)
 
End

Uso dei Componenti gb.net e gb.net.curl

Si potrà innanzitutto acquisire l'intero codice HTML di una pagina web, utilizzando i Componenti gb.net e gb.net.curl nel modo che segue: [Nota 1] 

Private mioHttp As NEW HttpClient As "mioHttp"
Private stringa As String  
 

Public Sub Button1_Click()  
                
  With mioHttp
    .URL = "https://www.pagina_web_da_caricare"           
    .Timeout = 15  
    .Get()
  End With

End


Public Sub mioHttp_Read()  
  
 Dim sBuf As String  
   
 Wait
 
 IF Lof(mioHttp) THEN   
   Read #mioHttp, sBuf, Lof(mioHttp)  
   stringa = stringa & sBuf  
 Endif
 
End
 

Public Sub mioHttp_Finished()
 
 Dim p, s As String  
 Dim i As Integer  
        
 Label1.Text = ("Pagina scaricata !")  
   
 Wait        
       
' La variabile stringa contiene la pagina html e viene visualizzata in una "TextArea":
 TextArea1.Text=stringa
       
 mioHttp.Close
 
End


Uso delle funzioni esterne della libreria Libcurl

Libcurl è una libreria gratuita lato-client di trasferimento dati con la sintassi URL, capace di supportare diversi protocolli.

Per poter fruire in Gambas delle risorse della libreria Libcurl, è necessario avere installata nel sistema e richiamare la libreria condivisa: "libcurl.so.4.8.0 ".


Mostriamo un esempio pratico: 

Library "libcurl:4.8.0"

Private Const CURLOPT_WRITEDATA As Integer = 10001
Private Const CURLOPT_URL As Integer = 10002
   
' CURL *curl_easy_init(void)
' Start a libcurl easy session.
Private Extern curl_easy_init() As Pointer

' CURLcode curl_easy_setopt(CURL *curl, CURLoption option, ...)
' Set options for a curl easy handle
Private Extern curl_easy_setopt(curl As Pointer, optionI As Integer, optionP As Pointer) As Integer
 
' CURLcode curl_easy_perform(CURL *curl)
' Perform a blocking file transfer.
Private Extern curl_easy_perform(curl As Pointer) As Pointer

' const char *curl_easy_strerror(CURLcode)
' Turn a CURLcode value into the equivalent human readable error string.
Private Extern curl_easy_strerror(CURLcode As Integer) As String

' void curl_easy_cleanup(CURL *curl)
' End a libcurl easy handle.
Private Extern curl_easy_cleanup(curl As Pointer)


Library "libc:6"

' FILE *fopen (const char *__restrict __filename, const char *__restrict __modes)
' Open a file and create a new stream for it.
Private Extern fopen(__filename As String, __modes As String) As Pointer

' int fclose (FILE *__stream)
' Close STREAM.
Private Extern fclose(__stream As Pointer) As Integer


Public Sub Main()

 Dim cu, url, pagina As Pointer
 Dim file_finale As String
 Dim ris As Integer
 
' Imposta l'indirizzo della pagina web di cui scaricare i dati html:
 url = Alloc("https://indirizzo/della/pagina/web")
  
' Imposta il percorso del nuovo file generato con i dati html scaricati della pagina web:
 file_finale = "/percorso/del/nuovo/file.html"
    
' Inizilizza la libreria Libcurl':
 cu = curl_easy_init()
 If cu = 0 Then Error.Raise("Impossibile inizializzare la libreria 'curl' !")
  
 curl_easy_setopt(cu, CURLOPT_URL, url)
   
' Apre in scrittura il percorso del nuovo file da salvare:
 pagina = fopen(file_finale, "wb")
   
' Scrive i dati html scaricati della pagina web nella variabile handle per la gestione del nuovo file da salvare:
 curl_easy_setopt(cu, CURLOPT_WRITEDATA, pagina)
  
' Scrive il nuovo file:
 ris = curl_easy_perform(cu)
 If ris <> 0 Then Error.Raise("Errore nella scrittura del file: " & curl_easy_strerror(ris))
   
   
' Va in chiusura e libera tutta la memoria precedentemente allocata:
 fclose(pagina)
 Free(url)
 curl_easy_cleanup(cu)
  
End


Riferimenti


Note

[1] Il codice è stato proposto dall'utente fsurfing del forum del sito www.gambas-it.org.

Estratto da "https://www.gambas-it.org/wiki/index.php?title=Acquisire_il_codice_HTML_di_una_pagina_web&oldid=36382"