Differenze tra le versioni di "Alsa e Gambas: Client e porte in Ricezione"

Versione delle 16:32, 24 nov 2011

Per la creazione del nostro Client e delle sue porte e per consentirne il collegamento ad ALSA, nella classe principale FMain.class sciveremo le seguenti righe:

Public alsa As CAlsa               ' classe che incapsula le funzioni ALSA


Public Sub Form_Open()

 Me.Center

 ' creare ("istanziare") la classe per poterla usare
 alsa = New CAlsa As "alsa"
 
 ' aprire alsa e assegnare un nome
 alsa.alsa_open("Applicativo in Ricezione dati")
 
End

Nella classe secondaria CAlsa.class richiameremo e porremo sostanzialmente tutte le funzioni, la libreria e le necessarie dichiarazioni di variabili che abbiamo conosciuto nel precedente progetto per l'invio dei dati Midi:

' Gambas-3 class file

Export

Public handle As Pointer
Private id As Integer
Private inport As Integer
 
 Library "libasound:2"

Const SND_SEQ_OPEN_DUPLEX As Integer = 3

' #define SND_SEQ_PORT_CAP_WRITE (1<<1)
Const SND_SEQ_PORT_CAP_WRITE As Integer = 2

' #define SND_SEQ_PORT_TYPE_MIDI_GENERIC   (1<<1)
Const SND_SEQ_PORT_TYPE_MIDI_GENERIC As Integer = 2

' #define SND_SEQ_PORT_TYPE_MIDI_GENERIC   (1<<20)
Const SND_SEQ_PORT_TYPE_APPLICATION As Integer = 1048576


' int snd_seq_open(snd_seq_t **seqp, const char * name, Int streams, Int mode)
Private Extern snd_seq_open(Pseq As Pointer, name As String, streams As Integer, mode As Integer) As Integer

' int snd_seq_set_client_name(snd_seq_t* seq, const char* name)
Private Extern snd_seq_set_client_name(seq As Pointer, name As String) As Integer

' int snd_seq_create_simple_port(snd_seq_t* seq, const char* name, unsigned int caps, unsigned int type)
Private Extern snd_seq_create_simple_port(seq As Pointer, name As String, caps As Integer, type As Integer) As Integer

' int snd_seq_client_id(snd_seq_t * seq)
Private Extern snd_seq_client_id(seq As Pointer) As Integer

' int snd_seq_connect_from(seq as pointer, myport as integer, src_client as integer, src_port as integer)
Private Extern snd_seq_connect_from(seq As Pointer, myport As Integer, src_client As Integer, src_port As Integer) As Integer


Public Sub alsa_open(myname As String)
 Dim err As Integer
 
 err = snd_seq_open(VarPtr(handle), "default", SND_SEQ_OPEN_DUPLEX, 0)
 printerr("Apertura di Alsa regolare !", err)
 If err < 0 Then error.RAISE("Errore nell'apertura di ALSA !")      ' gestione dell'errore
   
 snd_seq_set_client_name(handle, myname)
 id = snd_seq_client_id(handle)
 Print "Alsa Client-ID = "; id
 
 ' per poter leggere la propria porta, essa viene posta con capacità "Write", ossia "scrivibile" da parte dell'Altro dispositivo
 err = snd_seq_create_simple_port(handle, "Porta applicativo", SND_SEQ_PORT_CAP_WRITE, SND_SEQ_PORT_TYPE_MIDI_GENERIC + SND_SEQ_PORT_TYPE_APPLICATION)
 Print "Numero della porta input dell'applicazione = "; err
 If err < 0 Then error.Raise("Errore nella creazione della porta !")      ' gestione dell'errore
 inport = err
   
' si pongono: 14 (id del sistema ALSA) e 0 ( num. della sua porta)
' per connettere il nostro client ad Alsa e "ricevere" dati direttamente da essa.
 err = snd_seq_connect_from(handle, inport, 14, 0)      
 printerr("Subscribe inport", err)
 If err < 0 Then error.Raise("Error subscribe input device")      ' gestione dell'errore

End

Quindi inseriremo le funzioni per la gestione degli errori:

' ###   GESTIONE DELL'ERRORE   ### 

Private Extern snd_strerror(err As Integer) As Pointer

Public Sub errmsg(err As Integer) As String

   Return String@(snd_strerror(err))

End


Private Sub printerr(operation As String, err As Integer)
   If err < 0 Then Print operation; ": err="; err; " ("; errmsg(err); ")"
End

Nota

Se si intende, invece, ricevere messaggi Midi da una tastiera o altro dispositivo Midi esterno, dopo averlo collegato alla porta USB, si verificherà in console mediante il comando cat /proc/asound/seq/clients il suo numero identificativo e la sua porta. Quindi, se, per esempio, il numero identificativo della nostra tastiera esterna è 24 ed il numero della la sua porta è 0, bisognerà sostituire i parametri relativi al dispositivo sorgente nell'apposita funzione:

err = snd_seq_connect_from(handle, inport, 24, 0)