Assegnare ad un vettore i valori contenuti da un'area di memoria puntata da un Puntatore

Per assegnare ad un vettore i valori contenuti da un'area di memoria puntata da un Puntatore, è possibile adottare almeno due modalità.

Uso delle funzioni di Gambas di dereferenziazione dei Puntatori

La prima modalità prevede di assegnare ad ogni elemento del vettore i valori dell'area di memoria riservata, puntata dal Puntatore, dereferenziando man mano il Puntatore medesimo.

Mostriamo un semplice esempio pratico:

Public Sub Main()
 
 Dim p As Pointer
 Dim st As Stream
 Dim i as integer
 Dim bb As New Byte[8]
 Dim b As Byte
 
' Ai fini di questo esempio andiamo a riempire di valori un'area di memoria riservata, che sarà puntata da un Puntatore qui ritornato:
  p = Riempie_Puntatore()
  
   
' Assegnamo agli elementi del vettore i valori presenti nell'area di memoria allocata:
  For i = 0 To 7
    bb[i] = byte@(p + i)
  Next
   
' Verifichiamo infine in console il risultato del precedente l'assegnamento:
  For Each b In bb
    Print b
  Next
  
End


Private Function Riempie_Puntatore() As Pointer
 
 Dim vet As Byte[] = [1, 2, 3, 4, 5, 6, 7, 8]
 
' Ritorniamo alla routine principale l'indirizzo dell'area di memoria del vettore, nella quale sono contenuti i dati:
  Return vet.Data
 
End

Scrivendo con i "Memory Stream" nella proprietà ".Data" di una variabile vettoriale

In questo caso si provvederà a scrivere i valori, contenuti da un'area di memoria allocata, puntata da un Puntatore, in una variabile vettoriale attraverso la sua proprietà ".Data". ^{[nota 1]}

Ne mostriamo un esempio con un'applicazione a riga di comando:

Public Sub Main()
 
 Dim p As Pointer
 Dim bb As Byte[]
 Dim i As Integer
 Dim st As Stream
  
' Supponiamo di avere un'area di memoria riservata, puntata da un Puntatore "p", contenente quattro valori di tipo "Byte":
  p = Alloc(SizeOf(gb.Byte), 4)
  st = Memory p For Write
  For i = 0 To 3
    Write #st, 100 + i As Byte
  Next
  st.Close
  
  
' Supponiamo che la variabile vettoriale di tipo "Byte" con tenga anch'essa quattro valori, che andiamo a mostrare in console:
  bb = [0, 1, 2, 3]
  For i = 0 To bb.Max
     Print bb[i]
  Next
  Print
  
' Andiamo a modificare tutti i quattro valori della variabile vettoriale, scrivendoli con i "Memory Stream" nella sua proprietà ".Data":
  st = Memory bb.Data For Write
  For i = 0 To bb.Max
    Write #st, Byte@(p + i) As Byte
  Next
  
  st.Close
  Free(p)
  p = 0
  
  
' Andiamo avedere in console i nuovi 4 valori or ora assegnati alla variabile vettoriale:
  For i = 0 To bb.Max
    Print bb[i]
  Next
  
End

Uso della funzione esterna memcpy() di C

Possiamo anche utilizzare la funzione esterna memcpy() di C, richiamando la libreria libc.so.6 . Mostriamo un semplice esempio pratico:

Library "libc:6"

' void *memcpy (void * __dest, const void * __src, size_t __n)
' Copy N bytes of SRC to DEST.
Private Extern memcpy(dest As Pointer, __src As Pointer, n As Long) As Pointer


Public Sub Main()
 
 Dim p As Pointer
 Dim st As Stream
 Dim b As Byte
 Dim bb As New Byte[8]
 
' Allochiamo un'area di memoria riservata pari ad 8 byte:
  p = Alloc(8)
  
' Ai fini di questo esempio scriviamo alcuni dati nell'area di memoria allocata:
  st = Memory p For Write
  For b = 1 To 8
    Write #st, b * 10 As Byte
  Next
  st.Close
   
' Con la funzione esterna "memcpy()" copiamo nel vettore gli 8 valori presenti nell'area di memoria allocata:
  memcpy(bb.Data, p, 8)
   
' Verifichiamo in console l'assegnamento:
  For Each b In bb
    Print b
  Next
   
  Free(p)
  
End

Assegnando il Puntatore al membro Data della Struttura CARRAY dei sorgenti di Gambas

Un'altra modalità, più complessa, è quella di assegnare il Puntatore al membro data della Struttura CARRAY dei sorgenti di Gambas.

La Struttura CARRAY presente nel file header gbx_c_array.h dei sorgenti di Gambas è così definita:

typedef
       Struct {
		OBJECT object;
		int size;
		int count;
		TYPE type;
		void * data;
		int * Dim ;
		void * ref;
		}
	CARRAY;

laddove in particolare il membro:

• size è un intero che rappresenta la dimensione dei valori contenuti dal vettore (ossia è il tipo di valori del vettore);
• count' è un intero che rappresenta il numero di elementi costituenti il vettore;
• data è un Puntatore all'area di memoria riservata che contiene i dati contenuti dal vettore.

Pertanto, nel codice che appronteremo, bisognerà:
1) cambiare, qualora il numero di elementi del vettore sia diverso dalla dimensione dell'area puntata dal Puntatore (tenuto conto ovviamente dal tipo di valori), il valore presente nel membro count, assegnandogli il valore corrispondente al nuovo numero di elementi che il vettore dovrà possedere;
2) cambiare il valore del Puntatore all'area di memoria dei dati presente nel membro data, assegnando il nuovo Puntatore.

Se si sta scrivendo un'applicazione in ambiente grafico (come nell'esempio che segue), è opportuno, al fine di evitare errori di memoria, chiudere il programma con la funzione esterna risolutiva di C: exit() .

Mostriamo di seguito un esempio pratico:

' void exit(int status)
' Terminates the calling process immediately. Any open file descriptors belonging to the process are closed.
Private Extern C_exit(status As Integer) In "libc:6" Exec "exit"


Public Sub Form_Open()

 Dim bb As New Byte[]
 Dim pbb, count, dati, p As Pointer
 Dim st As Stream
 Dim b, n As Byte
 
' Ipotizziamo una situazione iniziale con un vettore contenente 5 elementi, tutti aventi un dato valore:
  bb = [11, 222, 33, 44, 55]

' Allochiamo 64 byte di area di memoria riservata, e la puntiamo con un "Puntatore":
  p = Alloc(64)
   
' Azzeriamo i byte dell'area di memoria precedentemente allocata, ma salvaguardando i valori preesistenti del vettore:
  st = Memory p For Write
  For b = 0 To 63
    n = 0
    If b <= bb.Max Then n = bb[b]
    Write #st, n As Byte
  Next
  st.Close
  
' Verifichiamo semplicemente il numero iniziale del numero degli elementi del vettore:
  Print bb.Count
  
' ---------------------------------------------
  
' Accediamo alla "Struttura" interna dell'oggetto "array" (il vettore dichiarato "bb") di Gambas:
  pbb = Object.Address(bb)
  
' Accediamo al membro "count" della predetta "Struttura" interna del vettore "bb":
  count = pbb + 20
  
' Accediamo al membro "data" della predetta "Struttura" interna del vettore "bb":
  dati = pbb + 32
  
' Impostiamo il nuovo numero di elementi che il vettore "bb" possiederà:
  st = Memory count For Write
  Write #st, 64 As Integer   ' Scriviamo "As Integer", poiché il membro "count" è un intero a 32 bit
  st.Close
  
' Verifichiamo il numero degli elementi del vettore dopo l'assegnazione del nuovo valore al membro "count" della "Struttura" interna del vettore "bb":
  Print bb.Count
  
' Assegnamo il nuovo "Puntatore"al membro "data" della "Struttura" interna del vettore "bb":
  st = Memory dati For Write
  Write #st, p As Pointer
  st.Close
  Free(p)
  
' Usiamo dunque la nuova attribuzione di area di memoria e di elementi al vettore "bb":
  bb[10] = 21
  bb[27] = 8
  bb[39] = 19
  bb[54] = 69
  
' Verifichiamo i valori presenti nel vettore "bb":
  For b = 0 To bb.Max
    Print b, bb[b]
  Next
  
' Chiudiamo con sicurezza il programma, liberando tutta la memoria utilizzata per esso:
  C_exit(0)
  
End

Note

[1] Vedasi anche la seguente pagina della WIKI: Leggere e scrivere in un vettore mediante i Memory Stream