Conoscere la quantità di memoria occupata dai tipi di dati di C e la loro locazione nei file header

Per conoscere la quantità di memoria occupata da un tipo di valore, definito in linguaggio C, ed in quale file header di sistema esso è dichiarato, possiamo utilizzare il seguente codice:

' long Dim_Tipo(void)
' Restituisce la quantità di memoria occupata dal tipo di valore cercato.
Private Extern Dim_Tipo() As Long In "/tmp/libTipo"


Public Sub Main()

 Dim header As String[] = ["/usr/include/x86_64-linux-gnu/bits/types.h",     ' i file header delle librerie ove ad esempio cercare
                           "/usr/include/x86_64-linux-gnu/sys/types.h",
                           "/usr/include/linux/types.h", "/usr/include/stdint.h",
                           "/usr/include/unistd.h"]
 Dim perc, s, tipo, ex As String
 Dim ss As String[]
 Dim sh As Short
 Dim d As Byte

' Cerchiamo un tipo valore:
 tipo = "u_int"

 Print "Inizio ricerca:\n\n"

 For Each perc In header
   s = File.Load(perc)
   ss = Split(s, "\x0A")
   sh = ss.Find("typedef " & tipo & " *", gb.Like)
   If sh > -1 Then
     Print "\n  " & ss[sh]
     Print "      trovato nel file header: '\e[34m" & perc & "\e[0m' - riga: "; sh + 1
   Endif
   sh = ss.Find("* " & tipo & ";", gb.Like)
   If sh > -1 Then
     Print "\n  " & ss[sh]
     Print "      trovato nel file header: '\e[34m" & perc & "\e[0m' - riga: "; sh + 1
   Endif
 Next
    
 d = CByte(DimensioneTipo(tipo))
 Print "\nIl tipo di dato '" & tipo & "' occupa [ "; d; " ] byte di memoria."

 Print "\n\e[31mFine ricerca"

End

Private Function DimensioneTipo(tp As String) As Long

 File.Save("/tmp/libTipo.c", "#include <bits/types.h>" &
           "\n#include <sys/types.h>" &
           "\n#include <linux/types.h>" &
           "\n#include <stdint.h>" &
           "\n#include <unistd.h>" &
           "\n\nlong Dim_Tipo() {" &
           "\n\n   return sizeof(" & tp & ");" &
           "\n}")

 Shell "gcc -o /tmp/libTipo.so /tmp/libTipo.c -shared -fPIC" Wait

 Return Dim_Tipo()

End