Differenze tra le versioni di "Convertire i formati audio mediante il Componente gb.media"

Versione delle 15:48, 15 set 2022

Utilizzando i plugin di GStreamer con le Classi MediaControl e MediaPipeline del Componente gb.media, è possibile effettuare diverse conversioni di file audio da un formato ad un altro.

Mostriamo di seguito qualche esempio pratico.

Conversione audio dal formato WAV al formato MP3

Private bo As Boolean


Public Sub Main()

 Dim fileaudio, datigrezzi As String
 Dim pl As MediaPipeline
 Dim src, wprs, cnv, lam, snk As MediaControl

 fileaudio = "/percorso/del/file.wav"

 datigrezzi = Temp

 pl = New MediaPipeline As "PLine"

 src = New MediaControl(pl, "filesrc")
 src["location"] = fileaudio

 wprs = New MediaControl(pl, "wavparse")
 cnv = New MediaControl(pl, "audioconvert")
 lam = New MediaControl(pl, "lamemp3enc")
 snk = New MediaControl(pl, "filesink")
 snk["location"] = datigrezzi
 
' Collega fra loro all'interno della pipeline gli oggetti MediaControl impostati:
 src.LinkTo(wprs)
 wprs.LinkTo(cnv)
 cnv.LinkTo(lam)
 lam.LinkTo(snk)

 pl.Play()
 
 Print "Durata del file audio: "; Time(0, 0, 0, pl.Duration * 1000)

 Repeat
   Write #File.Out, "\r\e[0mTempo convertito:     \e[31m" & Time(0, 0, 0, pl.Position * 1000)
   Flush #File.Out
   Wait 0.01
 Until bo = True

 Copy datigrezzi To "/tmp" &/ File.BaseName(fileaudio) & ".mp3"

 pl.Stop
 pl.Close

 Print "\n\e[0mConversione terminata !"

 Quit

End

Public Sub PLine_End()

 bo = True

End

Conversione audio dal formato WAV al formato OGG

Private bo As Boolean


Public Sub Main()
 
 Dim fileaudio, datigrezzi As String
 Dim pl As MediaPipeline
 Dim src, wprs, cnv, vor, mux, snk As MediaControl

 fileaudio = "/percorso/del/file.wav"

 datigrezzi = Temp

 pl = New MediaPipeline As "PLine"
  
 src = New MediaControl(pl, "filesrc")
 src["location"] = fileaudio
 
 wprs = New MediaControl(pl, "wavparse")
 cnv = New MediaControl(pl, "audioconvert")
 vor = New MediaControl(pl, "vorbisenc")
 mux = New MediaControl(pl, "oggmux")
 snk = New MediaControl(pl, "filesink")
 snk["location"] = datigrezzi
 
 src.LinkTo(wprs)
 wprs.LinkTo(cnv)
 cnv.LinkTo(vor)
 vor.LinkTo(mux)
 mux.LinkTo(snk)

 pl.Play()

 Print "Durata del file Midi: "; Time(0, 0, 0, pl.Duration * 1000)
 Repeat
   Write #File.Out, "\r\e[0mTempo convertito:     \e[31m" & Time(0, 0, 0, pl.Position * 1000)
   Flush #File.Out
   Wait 0.01
 Until bo = True

 Copy datigrezzi To "/tmp" &/ File.BaseName(fileaudio) & ".ogg"
 pl.Stop
 pl.Close

 Print "\n\e[0mConversione terminata !"

 Quit

End

Public Sub PLine_End()

 bo = True

End

Conversione audio dal formato MP3 al formato OGG

Private bo As Boolean


Public Sub Main()

 Dim fileaudio, datigrezzi As String
 Dim pl As MediaPipeline
 Dim src, map, mad, vor, mux, snk As MediaControl
 
 fileaudio = "/percorso/del/file.mp3"

 datigrezzi = Temp
  
 pl = New MediaPipeline As "PLine"

 src = New MediaControl(pl, "filesrc")
 src["location"] = fileaudio
  
 map = New MediaControl(pl, "mpegaudioparse")
 mad = New MediaControl(pl, "mpg123audiodec")
 vor = New MediaControl(pl, "vorbisenc")
 mux = New MediaControl(pl, "oggmux")
 snk = New MediaControl(pl, "filesink")
 snk["location"] = datigrezzi
 
 src.LinkTo(map)
 map.LinkTo(mad)
 mad.LinkTo(vor)
 vor.LinkTo(mux)
 mux.LinkTo(snk)
 
 pl.Play()
 
 Print "Durata del file Midi: "; Time(0, 0, 0, pl.Duration * 1000)
 Repeat
   Write #File.Out, "\r\e[0mTempo convertito:     \e[31m" & Time(0, 0, 0, pl.Position * 1000)
   Flush #File.Out
   Wait 0.01
 Until bo = True

 Copy datigrezzi To "/tmp" &/ File.BaseName(fileaudio) & ".ogg"
 pl.Stop
 pl.Close

 Print "\n\e[0mConversione terminata !"

 Quit

End

Public Sub PLine_End()

 bo = True

End

Conversione audio dal formato MP3 al formato WAV

Public Sub Main()
 
  Dim pl As MediaPipeline
  Dim src, map, mad, wav, snk As MediaControl
  Dim primofile As String
  Dim i As Integer
  
  primofile = "/tmp/primofile"
  
  pl = New MediaPipeline 
  
  src = New MediaControl(pl, "filesrc")
  src["location"] = "/percorso/del/file.mp3"
  
  map = New MediaControl(pl, "mpegaudioparse")
  mad = New MediaControl(pl, "mpg123audiodec")
  wav = New MediaControl(pl, "wavenc")
  snk = New MediaControl(pl, "filesink")
  snk["location"] = primofile
  
  src.LinkTo(map)
  map.LinkTo(mad)
  mad.LinkTo(wav)
  wav.LinkTo(snk)
  
  pl.Play()
  
  Repeat
    i = Stat(primofile).Size
    Wait 0.7
  Until Stat(primofile).Size == i
  
  Copy primofile To "/tmp/file.wav"
  pl.Stop
  pl.Close
  
End

Conversione audio dal formato MP3 al formato RAW

Con il seguente codice si otterranno da un file MP3 i dati audio grezzi nel formato: frequenza di campionamento = 44100, risoluzione = 16 bit, canali = 2.

Public Sub Main()
 
  Dim pl As MediaPipeline
  Dim src, par, dcd, snk As MediaControl
  Dim fil As MediaFilter
  Dim appoggio As String
  Dim i As Integer
  
  appoggio = Temp
  
  pl = New MediaPipeline 
  
  src = New MediaControl(pl, "filesrc")
  src["location"] = "/percorso/del/file.mp3"
  
  par = New MediaControl(pl, "mpegaudioparse")
  dcd = New MediaControl(pl, "mpg123audiodec")
  fil = New MediaControl(pl, "audio/x-raw, format=S16LE, rate=44100, channels=2, endianness=1234, width=16, depth=16")
  snk = New MediaControl(pl, "filesink")
  snk["location"] = appoggio

  src.LinkTo(par)
  par.LinkTo(dcd)
  dcd.LinkTo(fil)
  fil.LinkTo(snk)

  pl.Play()

  Repeat
    i = Stat(appoggio).Size
    Wait 1
  Until Stat(appoggio).Size == i
  
  If Exist("/tmp/file_RAW.raw") Then Kill "/tmp/file_RAW.raw"
  Copy appoggio To "/tmp/file_RAW.raw"

  pl.Stop
  pl.Close
  
End

Conversione audio con il plugin "decodebin"

Usando il plugin "decodebin" è possibile convertire qualsiasi formato audio in un altro desiderato.
Mostriamo un esempio, nel quale sarà convertito un file audio "OGG" in un file audio "WAV":

Public Sub Main()
 
  Dim pl As MediaPipeline
  Dim src, dcb, con, wav, snk As MediaControl
  Dim primofile As String
  Dim i As Integer
  
  primofile = "/tmp/primofile"
  
  pl = New MediaPipeline 
  
  src = New MediaControl(pl, "filesrc")
  src["location"] = "/percorso/del/file.ogg"
  
  dcb = New MediaControl(pl, "decodebin")
  con = New MediaControl(pl, "audioconvert")
  wav = New MediaControl(pl, "wavenc")
  snk = New MediaControl(pl, "filesink")
  snk["location"] = primofile
  
' Colleghiamo fra loro all'interno della pipeline gli oggetti MediaControl impostati:
  src.LinkTo(dcb)
  dcb.LinkLaterTo(con)
  con.LinkTo(wav)
  wav.LinkTo(snk)
  
  pl.Play()
  
  Repeat
    i = Stat(primofile).Size
    Wait 0.7
  Until Stat(primofile).Size == i
  
  Copy primofile To "/tmp/file.wav"
  pl.Stop
  pl.Close
  
End