Versione attuale delle 14:02, 13 gen 2024

Un file Midi può essere eseguito anche mediante una linea di pipeline gestita dalla funzione "gst parse launch()" del API di GStreamer, avendo l'accortezza di inserire alla fine della pipeline uno dei seguenti plugin: alsasink, pulsesink, openalsink.
E' necessario avere installata la libreria condivisa: "libgstreamer-1.0 ".

Mostriamo un esempio pratico:

Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean

' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, position As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()

 Dim midi As Pointer
 Dim durata, l As Long
 Dim volume As Float
 Dim tm As Date

 gst_init(0, 0)

 midi = gst_parse_launch("filesrc location=/percorso/del/file.mid ! decodebin ! audioconvert ! volume volume=7.0 ! alsasink", 0)

' Avviamo la riproduzione del file Midi:
 gst_element_set_state(midi, GST_STATE_PLAYING)

 Repeat
   gst_element_query_duration(midi, GST_FORMAT_TIME, VarPtr(durata))
   Wait 0.01
 Until durata > -1

 tm = Now

 Repeat
   l = DateDiff(tm, Now, gb.Millisecond)
   Write "\r\e[0mDurata: " & Time(0, 0, 0, durata / 1000000) & "      Pos. \e[31m" & Time(0, 0, 0, l)
   Wait 0.001
 Until l >= durata / 1000000

 gst_object_unref(midi)
 Print "\nEsecuzione terminata."

End

Uso dei plugin specifici di GStreamer per il Midi

Si potrà anche far uso dei plugin specifici di GStreamer per il Midi, che sono:

• midiparse
• fluiddec

In tal caso la stringa della pipeline dei plugin del codice, sopra esposto, sarà la seguente:

midi = gst_parse_launch("filesrc location=/percorso/del/file.mid ! midiparse ! fluiddec ! audioconvert ! volume volume=7.0 ! alsasink", 0)

Uso del solo plugin playbin

Va precisato che la riga di comando afferente alla funzione esterna gst parse launch() può essere impostata più brevemente anche così:

midi = gst_parse_launch("playbin uri=file:///percorso/del/file.mid", 0)

ma non sarà possibile utilizzare il plugin per la gestione del volume.

Riferimenti

• http://docs.gstreamer.com/display/GstSDK/gst-launch
• http://gstreamer.freedesktop.org/
• http://gstreamer.com/