Eseguire un file audio usando una linea di pipeline con la funzione 'gst parse launch()'

Da Gambas-it.org - Wikipedia.

La funzione esterna "gst_parse_launch()" della libreria GStreamer consente di costruire e gestire in modo semplice una pipeline GStreamer. La riga della pipeline gestita dalla funzione esterna "gst_parse_launch()" è un insieme di elementi separati da punti esclamativi (!). Le proprietà possono essere aggiunte agli elementi, sotto forma di: proprietà = valore.

Sarà necessario avere installata nel sistema e richiamare nell'applicazione Gambas la libreria condivisa: "libgstreamer-1.0 ".

Mostriamo un esempio pratico: 

Private audio As Pointer


Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()

 Dim durata As Long
 Dim tempus As Date
 Dim i As Integer

 gst_init(0, 0)

' Il percorso e il nome del file audio NON devono contenere spazi:
 audio = gst_parse_launch("filesrc location=/percorso/del/file/audio ! decodebin ! audioconvert ! alsasink", 0)   ' al posto di "alsasink" si può usare anche "pulsesink"

' Avviamo la riproduzione audio:
 gst_element_set_state(audio, GST_STATE_PLAYING)

 Repeat
   gst_element_query_duration(audio, GST_FORMAT_TIME, VarPtr(durata))
   Wait 0.01
 Until durata > -1

 tempus = Now

 Repeat
   i = DateDiff(tempus, Now, gb.Millisecond)
   Write "\r\e[0mDurata: " & Time(0, 0, 0, durata / 1000000) & "      Pos. \e[31m" & Time(0, 0, 0, i)
   Wait 0.001
 Until i >= (durata / 1000000)

 Termina()

End

 
Public Sub Application_Read()

 Dim s As String

 Input s

 Select Case s
   Case "p"
' Pone in pausa la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_PAUSED)
   Case "r"
' Riprende la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_PLAYING)
   Case "s"
' Arresta la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_NULL)
     Termina()
 End Select

End


Private Procedure Termina()

  gst_object_unref(audio)
  Print "\nEsecuzione terminata."
  Quit

End

Va precisato che la riga di comando afferente alla funzione esterna gst parse launch() può essere impostata più brevemente anche così: 

audio = gst_parse_launch("playbin uri=file:///percorso/del/file/audio", 0)


Plugin per l'esecuzione di soli specifici formati audio

Plugin per l'esecuzione dei soli file WAV

Volendo utilizzare lo specifico plugin "wavparse" per i soli file WAV, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue: 

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.wav ! wavparse ! alsasink", 0)

Plugin per l'esecuzione dei soli file MP3

Volendo utilizzare lo specifico plugin per i soli file MP3, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue: 

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.mp3 ! mpegaudioparse ! mpg123audiodec ! alsasink", 0)

Plugin per l'esecuzione dei soli file OGG

Volendo utilizzare gli specifici plugin per i soli file OGG, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue: 

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.ogg ! oggdemux ! vorbisdec ! audioconvert ! alsasink", 0)


Riferimenti

Estratto da "https://www.gambas-it.org/wiki/index.php?title=Eseguire_un_file_audio_usando_una_linea_di_pipeline_con_la_funzione_%27gst_parse_launch()%27&oldid=36113"