Versione delle 16:56, 1 ott 2016

La funzione esterna gst_parse_launch() della libreria GStreamer consente di costruire e gestire in modo semplice una pipeline GStreamer. La riga della pipeline gestita dalla funzione esterna gst_parse_launch() è un insieme di elementi separati da punti esclamativi (!). Le proprietà possono essere aggiunte agli elementi, sotto forma di: proprietà = valore.

Sarà necessario avere installata nel sistema e richiamare nell'applicazione Gambas la libreria dinamica condivisa: "libgstreamer-1.0"

Mostriamo un esempio pratico:

Private audio As Pointer


Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean
 
' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *cur)
' Queries an element for the stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()
 
 Dim pos, dur As Long
 Dim po, du As Date
     
  gst_init(0, 0)
  
  audio = gst_parse_launch("filesrc location=/percorso/del/file/audio ! decodebin ! audioconvert ! alsasink", 0)   ' al posto di "alsasink" si può usare anche "pulsesink"
  
' Avviamo la riproduzione audio:
  gst_element_set_state(audio, GST_STATE_PLAYING)
  
  Sleep 1
  
  Do
    gst_element_query_position(audio, GST_FORMAT_TIME, VarPtr(pos))
    gst_element_query_duration(audio, GST_FORMAT_TIME, VarPtr(dur))
    po = Date(0, 0, 0, 0, 0, 0, pos / 1000000)
    du = Date(0, 0, 0, 0, 0, 0, dur / 1000000)
    Write #File.Out, "\rDurata: " & du & "      " & "Tempo trascorso: " & po
    Wait 0.001
  Loop Until pos > dur
  
  Termina()
         
End


Public Sub Application_Read()

Dim s As String

 Input #File.In, s
  
 Select Case s
   Case "p"
' Pone in pausa la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_PAUSED)
   Case "r"
' Riprende la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_PLAYING)
   Case "s"
' Arresta la riproduzione del file mediale
     gst_element_set_state(audio, GST_STATE_NULL)
     Termina()
 End Select

End


Private Procedure Termina()
 
  gst_object_unref(audio)
  Print "\nEsecuzione terminata."
  Quit
  
End

Va precisato che la riga di comando afferente alla funzione esterna gst parse launch() può essere impostata più brevemente anche così:

audio = gst_parse_launch("playbin uri=file:///percorso/del/file/audio", 0)

Plugin per l'esecuzione dei file WAV

Volendo utilizzare lo specifico plugin "wavparse" per i file WAV, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue:

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.wav ! wavparse ! alsasink", 0)

Plugin per l'esecuzione dei file MP3

Volendo utilizzare lo specifico plugin "mad" per i file MP3, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue:

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.mp3 ! mad ! alsasink", 0)

Plugin per l'esecuzione dei file OGG

Volendo utilizzare gli specifici plugin per i file OGG, si può cambiare la riga di pipeline della funzione gst_parse_launch( ) come segue:

audio = gst_parse_launch("filesrc location=/percorso/del/file/audio.ogg ! oggdemux ! vorbisdec ! audioconvert ! alsasink", 0)

Riferimenti

• http://docs.gstreamer.com/display/GstSDK/gst-launch
• http://gstreamer.freedesktop.org/
• http://gstreamer.com/