Versione delle 03:48, 1 giu 2016

La libreria Libsmf consente di gestire i file Midi.

Per poter fruire nei programmi Gambas le sue risorse, è necessario installare e richiamare la libreria condivisa: "libsmf:0.0.0"

Mostriamo di seguito un semplice esempio per ottenere in formato testuale gli eventi Midi presenti in uno standard Mdi file:

Library "libsmf:0.0.0"

Public Struct smf_struct
  formati As Integer
  ppqn As Integer
  frames_per_second As Integer
  resolution As Integer
  number_of_tracks As Integer
  streamf As Pointer
  file_buffer As Pointer
  file_buffer_length As Integer
  next_chunk_offset As Integer
  expected_number_of_tracks As Integer
  tracks_array As Pointer
  last_seek_position As Float
  tempo_array As Pointer
End Struct
 
' smf_t * smf_load (const char * file_name)
' Loads SMF file.
Private Extern smf_load(file_name As String) As Smf_struct

' smf_event_t * smf_get_next_event (smf_t * smf)
' Next event, in time order, or NULL, if there are none left.
Private Extern smf_get_next_event(smf_t As Smf_struct) As Pointer

' char * smf_event_decode (const smf_event_t * event)
' Textual representation of the event given, or NULL, if event is unknown.
Private Extern smf_event_decode(smf_event As Pointer) As String

' void smf_delete (smf_t *smf)
' Frees smf and all it's descendant structures.
Private Extern smf_delete(smf As Smf_struct)


Public Sub Main()

 Dim smf As Smf_struct
 Dim evento As Pointer
  
  smf = smf_load("/percorso/del/file.mid")
   
  evento = smf_get_next_event(smf)
   
  While evento > 0
    Print smf_event_decode(evento)
    evento = smf_get_next_event(smf)
  Wend
  
  smf_delete(smf)

End

Riferimenti

• http://libsmf.sourceforge.net/api/