Generare un file immagine da una DrawingArea

Per generare un file immagine dal disegno di una DrawingArea, si possono adottare almeno due procedure:

• utilizzare le sole funzioni di Gambas;
• utilizzare le funzioni esterne delle librerie di X11 e di Imlib2.

Utilizzare le sole funzioni di Gambas

L'uso delle sole funzioni fornite dirattemente da Gambas richiede un procedimento più complesso, che può essere così brevemente esplicitato:

• disegno e/o scrivo nella DrawingArea;
• creo il file PDF mediante la proprietà .OutputFile della Classe Printer;
• utilizzando il file PDF, converto la pagina PDF in una Image (è necessario attivare il componente gb.pdf);
• quindi salvo detta Image con il suo metodo .Save in un file immagine.

Mostriamo di seguito un esempio:

Public Sub DrawingArea1_Draw()
 
  With Paint
    .Brush = Paint.Color(Color.Red)
    .MoveTo(200, 200)
    .RelLineTo(0, 100)
    .Stroke
    .DrawText("Testo con DrawText", 10, 10, 20, 20)
    .End
  End With
    
End


Public Sub Button1_Click()

  With Printer1
    .Configure
    .Orientation = 0
    .Paper = 2
    .Resolution = Desktop.Resolution
' Stampa/crea un file .pdf:
    .OutputFile = "/tmp/mio_file.pdf"
    .Print
  End With

End


Public Sub Printer1_Draw()

  DrawingArea1_Draw()

End


Public Sub Button2_Click()

 Dim pdf As New PdfDocument
 Dim i As New Image

  
  With pdf
    .Open("/tmp/mio_file.pdf")
' Se il file pdf è stato caricato correttamente...
    If .Ready = True Then
' ...allora convertiamo la prima pagina ("indice" delle pagine = 1) in una "Image":
      i = pdf[1].Image

' Infine salviamo l'Image in un file immagine
' (è necessario scegliere il tipo di file immagine fra quelli supportati):
      i.Save("/tmp/mio_file_immagine.xxx")

    Else
      Message.Error("<FONT color=darkred>Errore nel caricamento del file PDF !")
   
    Endif

  End With

End

Uso delle funzioni esterne del API di X11 e di ImLib2

L'uso delle risorse delle librerie esterne X11 e ImLib2 consente un procedimento molto più snello ripetto al precedente. Tale modalità richiede nel codice Gambas la dichiarazione delle seguenti librerie dinamiche condivise:

• "libX11.so.6.3.0"
• "libImlib2.so.1.4.6"

Mostriamo di seguito un semplice esempio, nel quale disegneremo all'interno di una DrawingArea una riga colorata con tutta la gamma dei colori dal blu al rosso. Al termine salveremo in un file immagine il disegno presente nella DrawingArea:

Library "libX11:6.3.0"

Private Enum XYBitmap = 0, XYPixmap, ZPixmap

' Display *XOpenDisplay(char *display_name)
' Opens a connection to the X server that controls a display.
Private Extern XOpenDisplay(display$ As String) As Pointer

' unsigned long XAllPlanes()
' Returns a value with all bits set to 1 suitable for use in a plane argument to a procedure.
Private Extern XAllPlanes() As Long

' XImage *XGetImage(Display *display, Drawable d, int x, int y, unsigned int width, unsigned int height, unsigned long plane_mask, int format)
' Returns a pointer to an XImage structure.
Private Extern XGetImage(displayP As Pointer, d As Long, xI As Integer, yI As Integer, wid As Integer, hei As Integer, plane_mask As Long, formatI As Integer) As Pointer
 
' XCloseDisplay(Display *display)
' Closes the connection to the X server for the display specified in the Display structure and destroys all windows.
Private Extern XCloseDisplay(displayP As Pointer)


Library "libImlib2:1.4.6"

' Imlib_Image imlib_create_image_using_data(int width, int height, DATA32 * data)
' Creates an image from the image data - in the format of a DATA32 (32 bits) per pixel in a linear array - specified with the width and the height specified.
Private Extern imlib_create_image_using_data(width As Integer, height As Integer, data As Pointer) As Pointer

' void imlib_context_set_image(Imlib_Image image)
' Sets the current image Imlib2 will be using with its function calls.
Private Extern imlib_context_set_image(Imlib_Image As Pointer)

' void imlib_image_set_has_alpha(char has_alpha)
' Sets the alpha flag for the current image.
Private Extern imlib_image_set_has_alpha(has_alpha As Boolean)

' void imlib_save_image(const char *filename)
' Saves the current image in the format specified by the current image's format settings to the filename.
Private Extern imlib_save_image(filename As String)


Public Sub Form_Open()
  
 DrawingArea1.Background = Color.White

End


Public Sub DrawingArea1_Draw()
  
 Dim c As Integer[] = [Color.Blue, Color.Green, Color.Yellow, Color.Red]
 Dim p As Float[] = [0, 0.34, 0.67, 1]
   
' Disegnamo all'interno della "DrawingArea":
  With Paint
    .Brush = .LinearGradient(10, 40, 300, 40, c, p)
    .Rectangle(10, 40, 300, 40)
    .Fill
    .End
  End With

End


Public Sub Button1_Click()

 Dim dsp, XImage, immago As Pointer
 Dim st as Stream
 
  dsp = XOpenDisplay(Null)
  If IsNull(dsp) Then Error.Raise("Impossibile aprire una connessione al server X !")
   
' Otteniamo un puntatore alla "Struttura" contenente i dati dell'immagine disegnata nella "DrawingArea":
  XImage = XGetImage(dsp, DrawingArea1.Handle, 0, 0, DrawingArea1.W, DrawingArea1.H, XAllPlanes(), ZPixmap)
  If IsNull(XImage) Then Error.Raise("Impossibile ottenere un 'Puntatore' ai dati dell'immagine della DrawingArea !")

' Otteniamo l'indirizzo di memoria dei dati grezzi dell'immagine puntati dalla Struttura "XImage":
  st = Memory XImage For Read
  Seek #st, 16
  Read #st, immago
  st.Close
 
' Viene creata l'immagine dai dati grezzi passando il "Puntatore" ai dati grezzi dell'immagine:
  immago = imlib_create_image_using_data(DrawingArea1.W, DrawingArea1.H, immago)
  If IsNull(immago) Then Error.Raise("Impossibile creare l'immagine dai dati grezzi acquisiti !")

' In alternativa ai "Memory Stream" è possibile scorrere all'interno del "Puntatore",
' per individuare l'indirizzo di memoria dei dati grezzi dell'immagine puntati dalla Struttura "XImage".
' Il "Puntatore", così impostato, viene successivamente passato alla funzione "imlib_create_image_using_data()"
' però adeguatamente dereferenziato con la funzione di dereferenziazione di un "Puntatore di Puntatore":
' XImage = XImage + 16
' immago = imlib_create_image_using_data(DrawingArea1.W, DrawingArea1.H, Pointer@(XImage))
' If IsNull(immago) Then Error.Raise("Impossibile creare l'immagine dai dati grezzi acquisiti !")

  imlib_context_set_image(immago)
   
' L'immagine creata viene salvata in un file immagine. Al nome del file immagine da creare va indicata l'estensione del formato immagine desiderato:
  imlib_save_image("/percorso/dove/salvare/il/file/immagine.xxx")
 
' Va in chiusura:
  XCloseDisplay(dsp)

End

Riferimenti

• X.Org project
• The Xlib Manual
• Imlib2 Library Documentation