Intercettare ed inviare dati Midi grezzi con le funzioni esterne del API di PortMidi

Da Gambas-it.org - Wikipedia.

La libreria PortMidi è una libreria per la gestione in tempo reale dei dati Midi in entrata ed in uscita. Essa fa parte di un assortimento di API e librerie create per la musica e per altri media.

E' possibile con alcune funzioni esterne della libreria PortMidi intercettare i dati Midi grezzi, provenienti da un dispositivo Midi, ed inviarli ad altri dispositivi Midi.

Sarà necessario avere installata nel proprio sistema e richiamare nel programma Gambas la libreria condivisa: ''libportmidi.so.0.0.0


Mostriamo di seguito un possibile codice che intercetta i dati Midi grezzi provenienti da un dispositivo esterno e li invia ad altro dispositivo Midi: 

Private s As String


Library "libportmidi:0.0.0"

Public Struct PmDeviceInfo
  structVersion As Integer
  interf As Pointer
  name As Pointer
  inputI As Integer
  outputI As Integer
  opened As Integer
End Struct

Public Struct PmEvent
  message As Integer
  timestamp As Integer
End Struct

Private Const PM_FILT_ACTIVE As Integer = 16384
Private Const PM_FILT_CLOCK As Integer = 256
Private Const PM_FILT_SYSEX As Integer = 1

' int Pm_CountDevices (void)
' Get devices count, ids range from 0 to Pm_CountDevices()-1.
Private Extern Pm_CountDevices() As Integer

' const char *Pm_GetErrorText( PmError errnum )
' Translate portmidi error number into human readable message.
Private Extern Pm_GetErrorText(errnum As Integer) As String

' const PmDeviceInfo* Pm_GetDeviceInfo( PmDeviceID id )
' Returns a pointer to a PmDeviceInfo structure referring to the device specified by id.
Private Extern Pm_GetDeviceInfo(id As Integer) As PmDeviceInfo
 
' PmError Pm_OpenInput( PortMidiStream** stream, PmDeviceID inputDevice, void *inputDriverInfo, int32_t bufferSize, PmTimeProcPtr time_proc, void *time_info )
' Open Input device.
Private Extern Pm_OpenInput(pstream As Pointer, inputDevice As Integer, inputDriverInfo As Pointer, bufferSize As Integer, time_proc As Pointer, time_info As Pointer) As Integer

' PmError Pm_OpenOutput (PortMidiStream **stream, PmDeviceID outputDevice, void *outputDriverInfo, long bufferSize, PmTimeProcPtr time_proc, void *time_info, long latency)
' Open Output device.
Private Extern Pm_OpenOutput(pstream As Pointer, outputDevice As Integer, outputDriverInfo As Pointer, bufferSize As Integer, time_proc As Pointer, latency As Long) As Integer
 
' PmError Pm_SetFilter( PortMidiStream* stream, int32_t filters )
' Sets filters on an open input stream to drop selected input types.
Private Extern Pm_SetFilter(pstream As Pointer, filters As Integer) As Integer

' int Pm_Read( PortMidiStream *stream, PmEvent *buffer, int32_t length )
' Retrieves midi data into a buffer, and returns the number of events read.
Private Extern Pm_Read(pstream As Pointer, buffer As PmEvent, lenght As Integer) As Integer

' PmError Pm_Write( PortMidiStream *stream, PmEvent *buffer, int32_t length )
' Writes midi data from a buffer.
Private Extern Pm_Write(pstream As Pointer, buffer As PmEvent, lenght As Integer) As Integer

' PmError Pm_Close( PortMidiStream* stream )
' Pm_Close(pstream) As Integer

' PmError Pm_Terminate( void )
' Library termination function.
Private Extern Pm_Terminate() As Integer

 
Public Sub Main()

 Dim err, i As Integer
 Dim info As PmDeviceInfo
 Dim midi_in, midi_out As Pointer

  Print "Dispositivi Midi e loro porte disponibili:\n"
 
  For i = 0 To Pm_CountDevices() - 1
    info = Pm_GetDeviceInfo(i)
    If IsNull(info.inputI) = False Then Print i; ": "; String@(info.interf); "  "; String@(info.name)
  Next
 
' Attende che sia inserito il numero del dispositivo Midi, da cui si riceverranno i dati Midi.
  Print "\nInserire il numero del dispositivo Midi, dal quale si riceveranno i dati Midi..."
  Input s
  Print "Porta del dispositivo Midi scelta:  "; s
  err = Pm_OpenInput(VarPtr(midi_in), Val(s), 0, 512, 0, 0)
  If err Then
    Print Pm_GetErrorText(err)
    Chiude()
  Endif
     
' Attende che sia inserito il numero del dispositivo Midi, al quale si invieranno i dati Midi.
  Print "\nInserire il numero del dispositivo Midi, al quale si invieranno i dati Midi..."
  Input s
  Print "Porta del dispositivo Midi scelta:  "; s
  err = Pm_OpenOutput(VarPtr(midi_out), Val(s), 0, 512, 0, 0)
  If err Then
    Print Pm_GetErrorText(err)
    Chiude()
  Endif
  s = Null
  
' Filtriamo i dati Midi ricevuti che non ci interessano:
  Pm_SetFilter(midi_in, PM_FILT_ACTIVE Or PM_FILT_CLOCK Or PM_FILT_SYSEX)
   
  Print "\nMidi Monitor pronto...\n"
  Print "Assicurarsi di aver connesso le porte dei dispositivi Midi coinvolti !"
   
  Print "Status", "nota", "velocità"
   
  While IsNull(s)
    Intercetta_Messaggi(midi_in, midi_out)
    Wait 0.01
  Wend
  
' Va in chiusura:
  Chiude(midi_out)
      
End


Private Procedure Intercetta_Messaggi(midIn As Pointer, midEx As Pointer)

 Dim pe As New PmEvent
 Dim count As Integer

' Riceve i dati Midi dal dispositivo Midi, leggendoli dalla sua porta in Uscita:
  count = Pm_Read(midIn, pe, 1)

  While count
  
    If count = 1 Then
' Volendo, possiamo stampare nella console i dati Midi ricevuti:
      Print (pe.message And &FF) And &f, (pe.message \ CInt(2 ^ 8)) And 255, (pe.message \ CInt(2 ^ 16)) And 255
' Invia i dati al dispositivo Midi, scrivendoli sulla sua porta in Entrata:
      Pm_Write(midEx, pe, 1)
    Else
' Va in chiusura:
      Chiude(midEx)
      Error.Raise("Errore nella ricezione dei Messaggi Midi:" & Pm_GetErrorText(count))
    Endif
    count = Pm_Read(midIn, pe, 1)
  
  Wend
 
End


Private Procedure Chiude(midi As Pointer)
 
  Pt_Close(midi)
  Pm_Terminate()
  Quit
 
End


' Intercetta un qualsiasi carattere inviato tramite Terminale/console e tastiera per interrompere il programma.
Public Sub Application_Read()
 
 Input #Last, s
 
End



Riferimenti

Estratto da "https://www.gambas-it.org/wiki/index.php?title=Intercettare_ed_inviare_dati_Midi_grezzi_con_le_funzioni_esterne_del_API_di_PortMidi&oldid=20247"