Versione delle 22:29, 23 set 2022

E' possibile intercettare i dati del mouse dai file-device:

• /dev/input/mouse(n)
• /dev/input/mice
• /dev/input/event(n)

laddove (n) è un numero d'indice.

Questa modalità ci consente di raccogliere i dati del mouse, pur stando con il suo puntatore al di fuori del Form del programma.gambas, oppure nel caso in cui lanciamo un'applicazione Gambas "a riga di comando" dal Terminale.

Bisogna ricordare che, essendo i predetti file-device del mouse protetti, dovremo ottenere preliminarmente i necessari permessi per la loro gestione.

Gestione mediante il file-device /dev/input/mouseN

Apertura del file-device mediante la Classe Process

Una modalità prevede l'apertura e la gestione del file-device /dev/input/mouseN mediante la Classe Process; laddove la "N" finale del file-device qui posta, rappresenta un numero progressivo.

Dopo aver lanciato il seguente codice, spostando molto lentamente il mouse senza cliccare alcun tasto, si vedrà spostare il Form coerentemente al verso dello spostamento del mouse. Tale azione verrà rilevata nella Label posta sul Form.
Se si clicca su un tasto, tale azione verrà rilevata nella Label.

Private pr As Process  
 
 
Public Sub Form_Open()  
 
' Se i permessi del file-device del mouse non consentono almeno la lettura del file-device...
  If Stat("/dev/input/mouse0").Auth <> "rwsrwxrwx" Then  
' ...allora li modifichiamo. E' necessario scrivere nell'istruzione seguente la nostra password.
' Modificati i permessi, potremo accedere al file-device protetto del mouse:
    Shell "echo 'MIA_PASSWORD' | sudo -S chmod 444 '/dev/input/mouse0'" Wait
  Endif 

' Modificati i permessi, potremo accedere al file-device del mouse e gestirlo in "lettura":
  pr = Shell "cat /dev/input/mouse0" For Read As "Processo"

End  

Public Sub Processo_Read()

 Dim s As String
 Dim i As Integer

' Leggiamo non più di 4 dati-carattere dal file-device del mouse.
' Il segno negativo impedisce di causare l'errore "Fine del file".
 Read #pr, s, -4

' Poiché una variabile stringa è comunque un puntatore ad un'area riservata, dereferenziamo detta variabile con l'apposita funzione di dereferenziazione che restituisce un tipo "Intero", e ne andiamo a leggere il valore:
  i = Int@(s)

  Select Case i   ' [Nota 1]

    Case 16711720                  ' spostamento in basso
      Me.Y = Me.Y + 1  
      Label1.Text = "in basso"    
    Case 65544                     ' spostamento in alto
      Me.Y = Me.Y - 1    
      Label1.Text = "in alto"    
    Case 264                       ' spostamento a destra
      Me.X = Me.X + 1    
      Label1.Text = "a destra"    
    Case 65304                     ' spostamento a sinistra
      Me.X = Me.X - 1    
      Label1.Text = "a sinistra"  
    Case 9                         ' premuto tasto sinistro
      Label1.Text = "tasto Sinistro"  
    Case 10                        ' premuto tasto destro
      Label1.Text = "tasto Destro"  
    Case 12                        ' premuto tasto centrale
      Label1.Text = "tasto Centrale"  
    Case 8                         ' qualsiasi tasto rilasciato
      Label1.Text = "tasto Rilasciato" 

  End Select

End

Un altro esempio analogo, nel quale si intende già eliminata la protezione del file-device relativo al mouse:

Private topo As Process
Private x As Integer
Private y As Integer
Private n As Integer
Private bb[3] As Byte

Public Sub Form_Open()

 With Me
   .Width = 220
   .Height = 150
   .Center
 End With

 With TextLabel1
   .Width = 200
   .Height = 120
   .X = 10
   .Y = 10
 End With

 x = Me.x
 y = Me.Y

 topo = Shell "cat /dev/input/mouse0" For Read As "Topo"

End

Public Sub Topo_Read()

 Dim b As Byte

 Repeat
   Read #topo, b
   bb[n] = b
   Inc n
 Until n == 3

 Select Case bb[0]
   Case 40               ' spostamento in basso
     y += 1
     TextLabel1.Alignment = Align.Bottom
     TextLabel1.Text = "in basso"
   Case 8          
     Select Case bb[2]
       Case 1            ' spostamento in alto
         y -= 2
         TextLabel1.Alignment = Align.Top
         TextLabel1.Text = "in alto"
       Case 0            ' spostamento a destra
         x += 2
         TextLabel1.Alignment = Align.Right
         TextLabel1.Text = "a destra"
     End Select
   Case 24               ' spostamento a sinistra
     x -= 2
     TextLabel1.Alignment = Align.Left
     TextLabel1.Text = "a sinistra"
 End Select

 Me.Move(x, y)
 n = 0
  
End

Apertura del file-device con Open.....For Read Watch

Quest'altra modalità prevede l'apertura e la gestione del file-device mediante l'istruzione Open.....For Read Watch:

Private fl As File
  
 
Public Sub Form_Open()  

' Se i permessi del file-device del mouse non consentono almeno la lettura del file-device...
  If Stat("/dev/input/mouse0").Auth <> "rwsrwxrwx" Then  
' ...allora li modifichiamo. E' necessario scrivere nell'istruzione seguente la nostra password.
' Modificati i permessi, potremo accedere al file-device protetto del mouse:
    Shell "echo 'MIA_PASSWORD' | sudo -S chmod 444 '/dev/input/mouse0'" Wait
  Endif

' ...quindi apriamo il file per la lettura ed per essere "osservato":
  fl = Open "/dev/input/mouse0" For Read Watch

End 

Public Sub File_Read()
  
 Dim s As String
 Dim i As Integer

' Leggiamo non più di 4 dati-carattere dal file-device del mouse.
' Il segno negativo impedisce di causare l'errore "Fine del file".
 Read #fl, s, -4

' Poiché una variabile stringa è comunque un puntatore ad un'area riservata, dereferenziamo detta variabile con l'apposita funzione di dereferenziazione che restituisce un tipo "Intero", e ne andiamo a leggere il valore:
  i = Int@(s)

  Select Case i   ' [Nota 1]

    Case 16711720                  ' spostamento in basso
      Me.Y = Me.Y + 1  
      Label1.Text = "in basso"    
    Case 65544                     ' spostamento in alto
      Me.Y = Me.Y - 1    
      Label1.Text = "in alto"    
    Case 264                       ' spostamento a destra
      Me.X = Me.X + 1    
      Label1.Text = "a destra"    
    Case 65304                     ' spostamento a sinistra
      Me.X = Me.X - 1    
      Label1.Text = "a sinistra"  
    Case 9                         ' premuto tasto sinistro
      Label1.Text = "tasto Sinistro"  
    Case 10                        ' premuto tasto destro
      Label1.Text = "tasto Destro"  
    Case 12                        ' premuto tasto centrale
      Label1.Text = "tasto Centrale"  
    Case 8                         ' qualsiasi tasto rilasciato
      Label1.Text = "tasto Rilasciato" 

  End Select
 
End

...un'applicazione pratica con Process

Come applicazione pratica di quanto descritto nella presente pagina, tenendo premuto con i tasti del mouse su una qualsiasi finestra di un programma esterno al nostro che appare sullo schermo, individueremo la finestra medesima e vi applicheremo alcuni comandi. Inoltre al rilascio di un qualunque pulsante conosceremo le coordinate assolute del puntatore del mouse in quel momento sullo schermo (anche se si è cliccato al di fuori di una finestra, semplicemente sulla Scrivania).
Si dovrà avere l'accortezza di inserire nel Form una TextArea, e di aprire le varie finestre, sulle quali testare il seguente codice, prima dell'applicativo.
E' necessario altresì attivare anche i Componenti "gb.desktop" e "gb.desktop.x11".

Private tp As Process


Public Sub Form_Open()

  If Stat("/dev/input/mouse0").Auth <> "rwsrwxrwx" Then
    Shell "echo 'MIA_PASSWORD' | sudo -S chmod 444 '/dev/input/mouse0'" Wait
  Endif

  tp = Shell "cat /dev/input/mouse0" For Read As "tp"

End

Public Sub tp_Read()

  Dim s As String
  Dim i As Integer
  Dim j As Byte
  Dim dw As DesktopWindow

' Leggiamo i dati dal file-device del mouse...
  Read #tp, s, -4

  i = Int@(s)
 
' Al rilascio di un qualunque tasto conosceremo le coordinate assolute del puntatore del mouse in quel momento sullo schermo (anche se si è cliccato al di fuori di una finestra).
' Se si vuole, invece, conoscere ad ogni spostamento del mouse le coordinate x,y del suo puntatore sullo schermo, allora basterà eliminare la sola parte dell'istruzione "IF", qui appresso.
  If i = 8 Then
    TextArea1.Text = "\nScreenX = " & Mouse.ScreenX & "\nScreenY = " & Mouse.ScreenY
  Endif
  
  For j = 1 To Desktop.Windows.Count - 1
    dw = New DesktopWindow(Desktop.Windows[j].Id)
    
' Esclude ogni azione sulla finestra dell'applicazione Gambas previste per le finestre degli altri programmi dalle successive istruzioni:  se il nome visibile della finestra elencata è uguale al nome dell'applicazione Gambas contenente il presente codice, allora si salta al giro successivo:
    If Desktop.Windows[j].VisibleName = Application.Name Then Continue

' Se invece l'Id della finestra "attiva" è uguale all'Id della finestra cliccata (e quindi resa appunto "attiva", sollevata) di un programma esterno...
    If Desktop.ActiveWindow = Desktop.Windows[j].Id Then

' ...allora verifica quale tasto del mouse è stato premuto:
      Select Case i
        Case 9         ' tasto Sinistro
' Vengono mostrate nella "TextArea" alcune proprietà della finestra cliccata (va rilevato che i valori vengono mostrati nella "TextArea" per il solo tempo in cui il mouse viene matenuto cliccato. Pertanto, per poter vedere agevolmente i suddetti risultati, suggeriamo di mantenere cliccato sulla finestra del programma esterno per qualche secondo).
          With dw
            TextArea1.Text = .VisibleName & "\n"
            TextArea1.Text &= "Id finestra: " & .Id & "\n"
            TextArea1.Text &= "Coord. X:    " & .X & "\n"
            TextArea1.Text &= "Coord. Y:    " & .Y & "\n"
            TextArea1.Text &= "Larghezza:   " & .W & "\n"
            TextArea1.Text &= "Altezza:     " & .H & "\n"
          End With
        Case 10         ' tasto Destro
' Se si clicca con il tasto destro del mouse, la finestra viene spostata in altre coordinate dello schermo:
          dw.Move(500, 300)
        Case 12         ' tasto Centrale
' Se, invece, si clicca sulla finestra con il tasto centrale del mouse, allora la finestra viene chiusa:
          dw.Close
      End Select  

    Endif

  Next

End

Gestione mediante il file-device: /dev/input/event...

L'esempio che riportiamo prevede la gestione dei dati del mouse intercettandoli dal suo file-device /dev/input/event... in un'applicazione "a riga di comando" lanciata da Terminale.

Bisognerà individuare l'esatto file-device del mouse il cui nome termina (sopra abbiamo sostituito l'ultimo carattere con tre puntini) con un numero.

Private fl As File
Private n As Integer


Public Sub Main()

  Dim s As String

' Individuiamo esattamente il file-device del mouse:
  s = File.Load("/proc/bus/input/devices")  
  
' Individuiamo la riga contenente il testo "Handlers=mouse, e raccogliamo l'ultima parola della riga medesima.
' Tale parola sarà il nome del file-device del mouse:
  s = Trim(Scan(s, "*Handlers=mouse* *\n*")[2])
  
' Per leggere il file-device individuato, bisogna avere i necessari permessi.  
' Pertanto, se non sono stati modificati i permessi del file-device, devono essere modificati (bisognerà inserire la propria password ! ):
  Shell "echo 'MIA_PASSWORD' | sudo -S chmod 444 /dev/input" &/ s Wait
  
' Apriamo il file-device in lettura e restiamo in attesa che arrivi qualche evento dal mouse:
  fl = Open "/dev/input" &/ s For Read Watch

End

Public Sub File_Read()

  Dim s As String
  Dim p As Pointer
  Dim l1, l2, l3, l4 As Long
  Dim sh1, sh2, sh3, sh4 As Short
  Dim i1, i2 As Integer
 
' Non appena giunge dal file-device qualche dato, lo leggiamo.
' Ogni evento che giunge dal mouse con-porta un flusso di più dati contemporaneamente.
' Per una più efficace ed intera intercettazione dell'intero fusso, lo leggiamo come stringa:
  Read #fl, s, -256

' Per poter successivamente scomporre i vari dati dall'unica stringa, creiamo da quella stringa un puntatore:
  p = Alloc(s)

' Quindi dereferenziamo il Puntatore con le apposite funzioni di dereferenziazione, e lo andiamo a leggere valore per valore:
  l1 = Long@(p)          ' Secondi
  l2 = Long@(p + 8)      ' Microsecondi
  sh1 = Short@(p + 16)   ' Tipo di evento mouse (2 spostamento mouse o rotazione rotellina; 4 clic)
  sh2 = Short@(p + 18)   ' Sotto-tipo di evento (0 spostamento mouse orizzontale; 1 spostamento verticale; 4 clic; 8 rotazione rotellina)
  i1 = Int@(p + 20)      ' Valore (-1 spostamento a sinistra o in alto, oppure rotellina ruotata indietro; 1 spostamento a destra o in basso, oppure rotellina ruotata in avanti)
  
  l3 = Long@(p + 24)     ' Secondi
  l4 = Long@(p + 32)     ' Microsecondi
  sh3 = Short@(p + 40)   ' Tipo di evento mouse (0 spostamento mouse o rotazione rotellina; 1 clic)
  sh4 = Short@(p + 42)   ' Sotto-tipo di evento (272 clic su tasto sinistro del mouse; 273  clic su tasto destro; 274 clic sulla rotellina/tasto centrale)
  i2 = Int@(p + 44)      ' Valore (0 tasto rilasciato; 1 tasto cliccato)


' Andiamo a vedere nel Terminale medesimo alcuni dati:
  Print sh1 & " " & sh2 & " " & i1 & " " & sh3 & " " & sh4 & " " & i2

' Sfruttando il valore dei "secondi" riportati dalla varibile "l1" (o anche da "l3") mostriamo nel Terminale il numero di secondi trascorsi dal momento in cui l'applicativo è stato lanciato:
  If n = 0 Then n = l1
  Print Time(0, 0, 0, (l1 - n) * 1000)

End

Note

[1] Per maggiore completezza riportiamo i tre valori intercettati dal file-device /dev/input/mouse0 del mouse con la modalità sopra mostrata negli esempi (testato con Ubuntu), che prevedono la gestione mediante il file-device /dev/input/mouse0, in base all'azione applicata sul mouse medesimo: