Versione delle 08:59, 22 set 2016

Rinviamo all'analogo capitolo sulla gestione delle funzioni delle API di GStreamer per l'audio: per l'esecuzione dei file Midi si adotteranno le medesime funzioni e risorse lì descritte, precisando che è necessario aver installato il file banco di suoni di default di Timidity: "/usr/share/sounds/sf2/TimGM6mb.sf2", oppure di FluidSynth: "/usr/share/sounds/sf2/FluidR3_GM.sf2".

• Eseguire un file Midi mediante le funzioni esterne del API di GStreamer

Pro memoria riportiamo l'esempio per un'applicazione a riga di comando, utilizzando però in questo caso un file Midi:

Private elem As Pointer


Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3
Private stato As Integer = GST_STATE_PLAYING

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_element_factory_make(const gchar *factoryname, Const gchar * name)
' Create a new element of the type defined by the given element factory.
Private Extern gst_element_factory_make(factoryname As String, name As String) As Pointer

' gchar * g_filename_to_uri (const gchar *filename, const gchar *hostname, GError **error)
' Converts an absolute filename to an escaped ASCII-encoded URI.
Private Extern g_filename_to_uri(filename As String, hostname As String, GError As Pointer) As String

' void g_object_set(gpointer object, const gchar *first_property_name, ...)
' Sets properties on an object.
Private Extern g_object_set(gobject As Pointer, property_name As String, value_1 As String, value_2 As String, value_3 As Float)

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration (GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gstelement As Pointer, gstformat As Pointer, duration As Pointer) As Boolean

' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *cur)
' Queries an element for the stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object .
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()

 Dim fileaudio as string
 Dim posizione, durata As Long
 Dim dur, pos As Date
 Dim volume As Float

  gst_init(0, 0)

  elem = gst_element_factory_make("playbin", "riproduzione")

  fileaudio = "/percorso/del/file.mid"

' Imposta il percorso del file Midi da eseguire:
  g_object_set(elem, "uri", g_filename_to_uri(fileaudio, Null, 0), Null, 0.0)
  
' Imposta il valore del volume (da 0 a 10) di esecuzione:
  volume = 7.0
  g_object_set(elem, "volume", Null, Null, volume)
  
' Avvia la riproduzione del file Midi:
  gst_element_set_state(elem, GST_STATE_PLAYING)
 
  While stato = GST_STATE_PLAYING
    gst_element_query_duration(elem, GST_FORMAT_TIME, VarPtr(durata))
    gst_element_query_position(elem, GST_FORMAT_TIME, VarPtr(posizione))
    dur = Date(0, 0, 0, 0, 0, 0, durata / 1000000)
    pos = Date(0, 0, 0, 0, 0, 0, posizione / 1000000)
    If (posizione > 0) And (pos >= dur) Then Break
    Write #File.Out, "\rDurata: " & dur & "      Pos. " & pos
    Wait 0.01
  Wend
   
  gst_object_unref(elem)
  Print "\nEsecuzione terminata."
  Quit
  
End


Public Sub Application_Read()
 
 Dim s As String
 
  Input #File.In, s
   
  Select Case s
    Case "p"                                               ' Pone in pausa la riproduzione del file Midi
      gst_element_set_state(elem, GST_STATE_PAUSED)
    Case "r"
      gst_element_set_state(elem, GST_STATE_PLAYING)       ' Riprende la riproduzione del file Midi
    Case "s"
      stato = gst_element_set_state(elem, GST_STATE_NULL)  ' Arresta la riproduzione del file Midi
  End Select
 
End

Va fatto notare che le due proprietà ("uri" e "volume") del plugin playbin potrebbero essere invocate con un'unica funzione g_object_set(). In tal caso della funzione esterna di GStreamer andrebbe dichiarata sostanzialmente come segue con 6 argomenti (il 2° ed il 3° relativi alla propietà "uri", mentre il 4°, il 5° ed il 6° relativi alla proprietà "volume"):

Private Extern g_object_set(gobject As Pointer, property_1 As String, value As String, Property_2 As String, value1 As String, value2 As Float)

e nel codice sarebbe così utilizzata:

g_object_set(elem, "uri", g_filename_to_uri(fileaudio, Null, 0), "volume", Null, volume)

Esecuzione mediante una linea di pipeline con la funzione gst parse launch()

Un file Midi può essere eseguito anche mediante una linea di pipeline gestita dalla funzione gst parse launch(), avendo l'accortezza di inserire alla fine della pipeline uno dei seguenti plugin: alsasink, pulsesink, openalsink.

Mostriamo un esempio pratico:

Private midi As Pointer


Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3
Private stato As Integer = GST_STATE_PLAYING

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean
 
' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *cur)
' Queries an element for the stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()
 
 Dim posizione, durata As Long
 Dim dur, pos As Date
     
  gst_init(0, 0)
  
  midi = gst_parse_launch("filesrc location=/percorso/del/file.mid ! decodebin ! audioconvert ! audioresample ! volume volume=7.0 ! alsasink", 0)
       
' Avviamo la riproduzione del file Midi:
  gst_element_set_state(midi, GST_STATE_PLAYING)
  
  While stato = GST_STATE_PLAYING
    gst_element_query_duration(midi, GST_FORMAT_TIME, VarPtr(durata))
    gst_element_query_position(midi, GST_FORMAT_TIME, VarPtr(posizione))
    dur = Date(0, 0, 0, 0, 0, 0, durata / 1000000)
    pos = Date(0, 0, 0, 0, 0, 0, posizione / 1000000)
    If (posizione > 0) And (pos >= dur) Then Break
    Write #File.Out, "\rDurata: " & Date(0, 0, 0, 0, 0, 0, durata / 1000000) & "      Pos. " & Date(0, 0, 0, 0, 0, 0, posizione / 1000000)
    Wait 0.01
  Wend
  
  gst_object_unref(midi)
  Print "\nEsecuzione terminata."
  Quit
      
End


Public Sub Application_Read()

Dim s As String

 Input #File.In, s
  
 Select Case s
   Case "p"
' Pone in pausa la riproduzione del file Midi
     gst_element_set_state(midi, GST_STATE_PAUSED)
   Case "r"
' Riprende la riproduzione del file Midi
     gst_element_set_state(midi, GST_STATE_PLAYING)
   Case "s"
' Arresta la riproduzione del file Midi
     stato = gst_element_set_state(midi, GST_STATE_NULL)
 End Select

End

Va precisato che la riga di comando afferente alla funzione esterna gst parse launch() può essere impostata più brevemente anche così:

audio = gst_parse_launch("playbin uri=file:///percorso/del/file.mid", 0)

ma non sarà possibile utilizare il plugin per la gestione del volume.

Riferimenti

• http://docs.gstreamer.com/display/GstSDK/gst-launch
• http://gstreamer.freedesktop.org/
• http://gstreamer.com/