La gestione mediante le funzioni esterne dell'API di SDL

Da Gambas-it.org - Wikipedia.

La libreria SDL è un API multi-piattaforma contenente funzioni per la gestione multimediale dell'audio e del video.


Per poter utilizzare le funzioni esterne di SDL in Gambas, si richiameranno anche separatamente per lo più le seguenti librerie (con le attuali versioni):

libSDL-1.2.so.0.11.4
libSDL_mixer-1.2.so.0.12.0
libSDL_sound-1.0.so.1.0.2

E' possibile riprodurre più suoni contemporaneamente utilizzando le funzioni della sub-libreria mixer audio multi-canale SDL_mixer.


Eseguire un file WAV intercettando il canale sul quale viene eseguito

E' possibile eseguire file WAV su flussi audio, definiti canali. L'esecuzione sarà effettuata usando la funzione Mix_PlayChannelTImed. Questa risorsa consente di eseguire sino a 32 file audio di formato WAV contemporaneamente. La predetta funzione intercetterà il canale sul quale il file WAV viene eseguito, restituendone un valore di tipo puntatore che ne consentirà la successiva gestione.

Di seguito mostreremo un semplice codice per eseguire un solo file audio WAV.

Private Const STEREO As Byte = 2


Library "libSDL-1.2:0.11.4"

Private Const AUDIO_S16SYS As Integer = 32784       ' Campioni a 16-bit
Private Const SDL_INIT_AUDIO As Byte = 16

' int SDL_Init(Uint32 flags)
' Loads the SDL dynamically linked library and initializes the subsystems specified by 'flags'.
Private Extern SDL_Init(flags As Integer) As Integer

' char * SDL_GetError(void)
' Retrieves a message about the last error that occurred.
Private Extern SDL_GetError() As String

' void SDL_Quit(void)
' Cleans up all initialized subsystems.
Private Extern SDL_Quit()


Library "libSDL_mixer-1.2:0.12.0"

' char * Mix_GetError(void)
' Retrieves a message about the last error that occurred.
Private Extern Mix_GetError() As String

' int Mix_OpenAudio(Int frequency, Uint16 Format, Int channels, Int chunksize)
' Initialize the mixer API.
Private Extern Mix_OpenAudio(frequency As Integer, sformat As Short, channels As Integer, chunksize As Integer) As Integer

' Mix_Chunk * Mix_LoadWAV_RW(SDL_RWops *src, int freesrc)
' Load file for use as a sample.
Private Extern Mix_LoadWAV_RW(src As Pointer, freesrc As Integer) As Pointer

' int Mix_PlayChannelTimed(int channel, Mix_Chunk *chunk, int loops, int ticks)
' Stop the sample after ticks milliseconds.
Private Extern Mix_PlayChannelTimed(channel As Integer, chunk As Pointer, loops As Integer, ticks As Integer) As Integer

' int Mix_Playing(int which)
' Check the status of a specific channel.
Private Extern Mix_Playing(which As Integer) As Integer

' void Mix_FreeChunk(Mix_Chunk *chunk)
' Free the memory used in chunk.
Private Extern Mix_FreeChunk(chunk As Pointer)

' void Mix_CloseAudio(void)
' Shutdown and cleanup the mixer API.
Private Extern Mix_CloseAudio()


Library "libSDL_sound-1.0:1.0.2"

' SDL_RWops *SDL_RWFromFile(const char *file, const char *mode)
' Create a new SDL_RWops structure for reading from and/or writing to a named file.
Private Extern SDL_RWFromFile(src As String, mode As String) As Pointer


Public Sub Main()

 Dim err, channel As Integer
 Dim audio_rate As Integer = 44100   ' Imposta la frequenza che verrà usata da "SDL_mixer"
 Dim audio_buffers As Short = 4096   ' Determina la quantità di blocchi di memoria utilizzati per incamerare ed eseguire i campioni audio
 Dim fl, sound As Pointer


' Inizializza il dispositivo SDL audio:
   err = SDL_Init(SDL_INIT_AUDIO)
   If err < 0 Then Error.Raise("Impossibile inizializzare la libreria SDL: " & SDL_GetError())

' Inizializza la libreria "SDL_mixer" con specifiche impoostazioni audio:
   err = Mix_OpenAudio(audio_rate, AUDIO_S16SYS, STEREO, audio_buffers)
   If err <> 0 Then Error.Raise("Impossibile inizializzare l'audio: " & Mix_GetError())
   
' Carica il file WAV:
   fl = SDL_RWFromFile("/percorso/del/file.wav", "rb")
   If fl = 0 Then Error.Raise("Errore nel caricamento del file !")

   sound = Mix_LoadWAV_RW(fl, 1)

' Esegue il file WAV caricato, ed intercetta il canale sul quale viene eseguito.
' Passando il valore -1 al primo argomento della funzione, il campione audio sarà eseguito sul primo canale audio disponibile:
   channel = Mix_PlayChannelTimed(-1, sound, 0, 0)
   If channel = -1 Then Error.Raise("Impossibile eseguire il file WAV: " & Mix_GetError())

' Attende che sia terminato il file WAV:
   While Mix_Playing(channel) <> 0
     Wait 0.01
   Wend

' Libera la memoria precedentemente allocata per l'esecuzione sonora:
   Mix_FreeChunk(sound)
 
' Chiude l'interfaccia audio SDL e SDL_mixer:
   Mix_CloseAudio()
 
   SDL_Quit()

End


Eseguire due o più file audio WAV

Di seguito mostreremo un codice esemplificativo, nel quale verranno eseguiti due file WAV:

Private Const AUDIO_S16SYS As Integer = 32784       ' Campioni a 16-bit
Private Const SDL_INIT_AUDIO As Byte = 16
Private Const STEREO As Byte = 2


Library "libSDL-1.2:0.11.4"

' int SDL_Init(Uint32 flags)
Private Extern SDL_Init(flags As Integer) As Integer

' char * SDL_GetError(void)
Private Extern SDL_GetError() As String

' void SDL_Quit(void)
Private Extern SDL_Quit()


Library "libSDL_mixer-1.2:0.12.0"

' char * Mix_GetError(void)
Private Extern Mix_GetError() As String

' int Mix_OpenAudio(Int frequency, Uint16 Format, Int channels, Int chunksize)
Private Extern Mix_OpenAudio(frequency As Integer, formatSh As Short, channels As Byte, chunksize As Integer) As Integer

' Mix_Chunk * Mix_LoadWAV_RW(SDL_RWops *src, int freesrc)
Private Extern Mix_LoadWAV_RW(src As Pointer, freesrc As Integer) As Pointer

' int Mix_PlayChannelTimed(int channel, Mix_Chunk *chunk, int loops, int ticks)
Private Extern Mix_PlayChannelTimed(channel As Integer, chunk As Pointer, loops As Integer, ticks As Integer) As Integer

' int Mix_Playing(int which)
Private Extern Mix_Playing(which As Integer) As Integer

' void Mix_FreeChunk(Mix_Chunk *chunk)
Private Extern Mix_FreeChunk(chunk As Pointer)

' void Mix_CloseAudio(void)
Private Extern Mix_CloseAudio()


Library "libSDL_sound-1.0:1.0.2"

' SDL_RWops *SDL_RWFromFile(const char *file, const char *mode)
Private Extern SDL_RWFromFile(src As String, mode As String) As Pointer


Public Sub Button1_Click()

 Dim err As Integer
 Dim channel as New Integer[]
 Dim audio_rate As Integer = 44100
 Dim audio_buffers As Short = 4096
 Dim fl, sound As New Pointer[]
 Dim percorsoFile As String[]
 Dim canale As Byte = 1


   percorsoFile = ["/percorso/del/primo/file.wav", "/percorso/del/secondo/file.wav"]


' Inizializza il dispositivo SDL audio:
   err = SDL_Init(SDL_INIT_AUDIO)
   If err < 0 Then Error.Raise("Impossibile inizializzare la libreria SDL: " & SDL_GetError())

' Inizializza la libreria "SDL_mixer" con specifiche impoostazioni audio:
   err = Mix_OpenAudio(audio_rate, AUDIO_S16SYS, STEREO, audio_buffers)
   If err <> 0 Then Error.Raise("Impossibile inizializzare l'audio: " & Mix_GetError())
   
' Carica il primo file WAV:
   fl.Add(SDL_RWFromFile(percorsoFile[0], "rb"))
   If IsNull(fl[0]) Then Error.Raise("Errore nel caricamento del 1° file !")

' Carica il secondo file WAV:
   fl.Add(SDL_RWFromFile(percorsoFile[1], "rb"))
   If IsNull(fl[1]) Then Error.Raise("Errore nel caricamento del 2° file !")
 
   With sound
     .Add(Mix_LoadWAV_RW(fl[0], 1))
     .Add(Mix_LoadWAV_RW(fl[1], 1))
   End With

' Esegue contemporaneamente entrambi i file WAV caricati , ed intercetta il rispettivo canale sul quale ciascuno di essi viene eseguito.
' Passando il valore -1 al primo argomento della funzione, il campione audio sarà eseguito sul primo canale audio disponibile:
   channel.Add(Mix_PlayChannelTimed(-1, sound[0], 0, 0))
   If channel[0] = -1 Then Error.Raise("Impossibile eseguire il 1° file WAV: " & Mix_GetError())

   channel.Add(Mix_PlayChannelTimed(-1, sound[1], 0, 0))
   If channel[1] = -1 Then Error.Raise("Impossibile eseguire il 2° file WAV: " & Mix_GetError())

' Verifica quale file wav possiede la maggiore dimensione: 
   If Stat(percorsoFile[0]).Size > Stat(percorsoFile[1]).Size Then canale = 0

' Attende che sia terminato il file WAV di maggiore dimensione
' (e quindi presumibilmente quello con maggiore durata):
   While Mix_Playing(canale) <> 0
     Wait 0.01
   Wend

' Libera la memoria precedentemente allocata per l'esecuzione dei due file wav:
   Mix_FreeChunk(sound[0])
   Mix_FreeChunk(sound[1])
 
' Chiude l'interfaccia audio SDL e SDL_mixer:
   Mix_CloseAudio()
 
   SDL_Quit()

End


Eseguire gli altri formati di file audio

Per poter eseguire i file audio di altro formato (ma compreso anche lo stesso formato WAV) |1|, bisognerà utilizzare la funzione Mix_PlayMusic appartenente alla libreria libSDL_mixer-1.2.so.0.12.0. Detta funzione non consente di poter eseguire più file contemporaneamente.

Private Const AUDIO_S16SYS As Integer = 32784       ' Campioni a 16-bit
Private Const SDL_INIT_AUDIO As Byte = 16
Private Const STEREO As Byte = 2


Library "libSDL-1.2:0.11.4"

' int SDL_Init(Uint32 flags)
Private Extern SDL_Init(flags As Integer) As Integer

' char * SDL_GetError(void)
Private Extern SDL_GetError() As String

' void SDL_Quit(void)
Private Extern SDL_Quit()


Library "libSDL_mixer-1.2:0.12.0"

' char * Mix_GetError(void)
Private Extern Mix_GetError() As String

' int Mix_OpenAudio(Int frequency, Uint16 Format, Int channels, Int chunksize)
Private Extern Mix_OpenAudio(frequency As Integer, formatSh As Short, channels As Byte, chunksize As Integer) As Integer

' Mix_Music *Mix_LoadMUS(const char *file)
Private Extern Mix_LoadMUS(file As String) As Pointer

' int Mix_PlayMusic(Mix_Music *music, int loops)
Private Extern Mix_PlayMusic(music As Pointer, loops As Integer) As Integer

' Int Mix_PlayingMusic()
Private Extern Mix_PlayingMusic() As Integer

' void Mix_FreeChunk(Mix_Chunk *chunk)
Private Extern Mix_FreeChunk(chunk As Pointer)

' void Mix_CloseAudio(void)
Private Extern Mix_CloseAudio()


Public Sub Button1_Click()

 Dim err As Integer
 Dim audio_rate As Integer = 44100   ' Imposta la frequenza che verrà usata da "SDL_mixer"
 Dim audio_buffers As Short = 4096   ' Determina la quantità di blocchi di memoria utilizzati per incamerare ed eseguire l'audio
 Dim music As Pointer


' Inizializza il dispositivo SDL audio:
   err = SDL_Init(SDL_INIT_AUDIO)
   If err < 0 Then Error.Raise("Impossibile inizializzare la libreria SDL: " & SDL_GetError())

' Inizializza la libreria "SDL_mixer" con specifiche impoostazioni audio:
   err = Mix_OpenAudio(audio_rate, AUDIO_S16SYS, STEREO, audio_buffers)
   If err <> 0 Then Error.Raise("Impossibile inizializzare l'audio: " & Mix_GetError())


' Carica il file audio:
   music = Mix_LoadMUS("/percorso/del/file_audio")
   If IsNull(music) Then Error.Raise("Impossibile caricare il file audio: " & Mix_GetError())

' Esegue il file audio. Se il secondo argomento è posto a 0 il file sarà eseguito soltanto una volta.
' Se è posto a -1 il file sarà esguito all'infinito:
   err = Mix_PlayMusic(music, 0)
   If err < 0 Then Error.Raise("Impossibile eseguire il file audio: " & Mix_GetError())


' Attende che sia terminato il file audio:
   While Mix_PlayingMusic() <> 0
     Wait 0.01
   Wend

' Libera la memoria precedentemente allocata per l'esecuzione sonora:
   Mix_FreeChunk(music)
 
' Chiude l'interfaccia audio SDL e SDL_mixer:
   Mix_CloseAudio()
 
   SDL_Quit()

End


Note

[1] I formati eseguibili sono i seguenti:

  • .WAV (WAV/RIFF)
  • .VOC (Creative Labs' Voice format)
  • .MP3 (MPEG-1 Layer 3 support)
  • .MID (Musical Instrument Digital Interface)
  • .MOD (MOD file: .mod .xm .s3m .669 .it .med ed altri)
  • .OGG (Ogg file)
  • .SPX (Speex file)
  • .SHN (Shorten file)
  • .RAW (Raw sound data in any format)
  • .AU (Sun's Audio format)
  • .AIFF (Audio Interchange format)
  • .FLAC (Lossless audio compression)


Riferimenti