Differenze tra le versioni di "Ottenere la descrizione del tipo di errore dai file header "errno-base.h" e "errno.h""

Versione delle 08:38, 6 ott 2022

Molte funzioni esterne in caso errore ritornano tipi di errore contenuti e descritti nei file header errno-base.h e errno.h.

Essendo tali file header sostanzialmente dei file di testo, è abbastanza agevole, volendo, estrarre da essi sulla base del valore di errore, ritornato dalla funzione esterna, la descrizione di questo presente nel file header.

Nell'esempio che segue, avremo una libreria condivisa esterna, da noi scritta in C, con la quale fingiamo di provocare un errore "EINVAL" (codice num. 22), che sarà successivamente raccolto dal nostro codice Gambas mediante il Metodo ".Error" della Classe nativa System.

' void simula_errore()
Private Extern simula_errore() In "/tmp/liberrore"


Public Sub Main()

 Dim err As Integer
 Dim fl As File
 Dim s As String

' Va a creare la libreria condivisa esterna, che simulerà la sollevazione di un errore "9":
 Creaso()

' Simula la sollevazione di un errore "EINVAL":
 simula_errore()

' Raccoglie l'errore:
 err = System.Error

' Per intercettare l'errore può usare anche il Metodo "System.GetExternSymbol()":
' Dim p As Pointer
' p = System.GetExternSymbol("/tmp/liberrore", "errno")
' err = Int@(p)

 fl = Open "/usr/include/asm-generic/errno-base.h"

 For Each s In fl.Lines
   If s Like "* " & CStr(err) & " *" Then Print "Errore n. "; CStr(err); ": "; Scan(s, "*/*/*")[1]
 Next
 fl.Close

 fl = Open "/usr/include/asm-generic/errno.h"
 For Each s In fl.Lines
   If s Like "* " & CStr(err) & " *" Then Print "Errore n. "; CStr(err); ": "; Scan(s, "*/*/*")[1]
 Next
 fl.Close

End

Private Procedure Creaso()

 File.Save("/tmp/liberrore.c", "#include <errno.h>\n\n" &
                               "void simula_errore() {\n" &
                               "   errno = EINVAL;\n}")

 Shell "gcc -o /tmp/liberrore.so /tmp/liberrore.c -shared -fPIC" Wait

End