Versione delle 17:53, 10 ago 2019

Utilizzando i plugin di GStreamer con le Classi MediaControl e MediaPipeline del Componente gb.media, è possibile ottenere un file audio da un file MIDI.

I plugin specifici da utilizzare per il MIDI sono:

• midiparse: interpreta i file MIDI e li converte in eventi MIDI;
• fluiddec: effettua il render degli eventi MIDI in campioni audio grezzi.

Mostriamo di seguito un esempio pratico, nel quale si otterrà un file WAV da un file MIDI:

Public Sub Main()
 
 Dim pl As MediaPipeline
 Dim src, par, fdc, res, cnv, vol, enc, snk As MediaControl
 Dim flt As MediaFilter
 Dim filemidi, primofile As String
 Dim tm As Date
 Dim i As Integer
 
 filemidi = "/percorso/del/file.mid"
 primofile = "/tmp/primofile"
  
 pl = New MediaPipeline 
   
 src = New MediaControl(pl, "filesrc")
 src["location"] = filemidi   ' "location" è una proprietà del plugin "filesrc"
  
 par = New MediaControl(pl, "midiparse")
 fdc = New MediaControl(pl, "fluiddec")
 res = New MediaControl(pl, "audioresample")
 cnv = New MediaControl(pl, "audioconvert")
 flt = New MediaFilter(pl, "audio/x-raw,rate=44100,channels=2")
 vol = New MediaControl(pl, "volume")
 vol["volume"] = 4.0                          ' "volume" è una proprietà dell'omonimo plugin "volume"
 enc = New MediaControl(pl, "wavenc")
 snk = New MediaControl(pl, "filesink")
 snk["location"] = primofile                  ' "location" è una proprietà del plugin "filesink"
  
 src.LinkTo(par)
 par.LinkTo(fdc)
 fdc.LinkTo(res)
 res.LinkTo(cnv)
 cnv.LinkTo(flt)
 flt.LinkTo(vol)
 vol.LinkTo(enc)
 enc.LinkTo(snk)
  
 pl.Play()
  
 Print "\nDurata del file Midi: " & Date(0, 0, 0, 0, 0, 0, pl.Duration * 1000)
 tm = Now
 Repeat
   i = DateDiff(tm, Now, gb.Millisecond)
   Write "\rTempo trascorso: " & CStr(Date(0, 0, 0, 0, 0, 0, i))
   Sleep 0.01
 Until i \ 1000 >= pl.Duration
  
 Copy primofile To "/tmp" &/ File.BaseName(filemidi) & ".wav"
 pl.Stop
 pl.Close
  
End

Riferimenti

• https://cgit.freedesktop.org/gstreamer/gstreamer/tree/docs/random/uraeus/gstreamer_and_midi.txt