Versione delle 07:55, 29 giu 2023

Read legge da un flusso di dati (file o stream). I dati letti vengono memorizzati in una adeguata variabile:

Read #file, variabile   [Nota 1]

La quantità di byte letti dal file è determinata dal tipo di dato, al quale appartiene la variabile ove verranno salvati i dati. Così, se la variabile, destinata a contenere i dati letti dal file o dallo stream, è di tipo Byte, verrà letto un solo byte di dati; se è di tipo Short, saranno letti due byte di dati; e così via.
Insomma, la funzione Read legge una quantità di byte-dati dal file pari alla quantità che può essere memorizzata nella variabile del tipo di dati come dichiarata e utilizzata.
Esempio:

Public Sub Main()

 Dim fl As File
 Dim i As Integer
  
 fl = Open "/percorso/del/file" For Read
  
' Poiché la variabile "i" è un Intero (Integer), "Read" legge dal file una quantità di byte-dati pari al risultato di "SizeOf(gb.Integer)", ossia 4 byte, e li memorizza in quella variabile:
 Read #fl, i
  
 Print i
 
' Chiude il file con l'istruzione "Close":
 Close #fl
  
End

Salvo diversa impostazione del puntatore del file mediante l'uso della risorsa "Seek", la lettura è effettuata a cominciare dal 1° byte di dati (indice 0) del file o dello stream.

Va ricordato che ad ogni lettura con Read il puntatore interno del file avanza di una quantità di byte pari alla quantità di byte di dati letti.

Al termine della lettura il flusso di dati va sempre chiuso con l'apposito Metodo ".Close()" della Classe File, oppure mediante la risorsa "Close".

Leggere tutti i byte del file o dello stream

Se si intende leggere tutti i byte presenti all'interno del file, cioè l'intero file, si potranno adottare diverse modalità.

Uso della funzione "Eof()"

La funzione "Eof()" combinata con un ciclo di lettura consente di leggere dati dal file fino al termine di questo, evitando un errore di "Fine file".

Public Sub Main()

 Dim fl As File
 Dim b As Byte

' Apre il file in lettura e, affinché possa essere gestito, lo carica nella variabile di tipo "File":
 fl = Open "/percorso/del/file" For Read

' Avvia un ciclo per leggere tutti i byte fino alla fine del file:
 While Not Eof(fl)

' Ad ogni passaggio legge un byte e lo inserisce nella variabile “b“ (il puntatore interno del file avanza - in questo caso - di 1 byte ad ogni lettura !):
   Read #fl, b

 ' Mostra a fini didattici i byte in formato esadecimale:
   Print Hex(b, 2)

 Wend

' Chiude il file questa volta con il Metodo ".Close()" della Classe "File":
 fl.Close

End

Uso della funzione "Lof()"

Usando invece una variabile di tipo stringa combinata con la funzione "Lof()", il file sarà letto per la sua intera lunghezza:

Public Sub Main()

 Dim fl As File
 Dim s As String
  
 fl = Open "/percorso/del/file" For Read
  
' Leggiamo ogni byte del file come carattere ASCII, per l'intera lunghezza del file medesimo.
' Avremo quindi per ogni byte un valore di tipo "String":
 Read #fl, s, Lof(fl)
  
 Print s
 
 Close #fl
  
End

oppure anche con un ciclo e la funzione "Seek()" leggendo un byte alla volta:

Public Sub Main()

 Dim fl As File
 Dim b As Byte

 fl = Open "/percorso/del/file" For Read

 While Seek(fl) < Lof(fl)
   Read #fl, b
   Print Hex(b, 2)
 Wend

 fl.Close

End

Leggere una quantità arbitraria di dati da un file

All'inizio si è detto che la quantità di dati letti da un da un file è determinata dal tipo di variabile. Se si intende, invece, far leggere una quantità da noi stabilita di dati, sarà necessario leggerli come caratteri ASCII e salvarli conseguentemente in una variabile di tipo String.
Il numero di byte-dati da leggere sarà impostato nel terzo parametro della riga di comando di "Read":

Read #variabile_file, variabile_stringa, n

laddove n rappresenta appunto la quantità di byte da leggere a partire dal primo (indice 0).

Esempio:

Public Sub Main()

 Dim s As String

 fl = Open "/percorso/del/file" For Read 
 
' Legge soltanto i primi dieci byte del file:
 Read #fl, s, 10

 Print s

 fl.Close

End

Se però il file è formato da un numero inferiore di dati-byte rispetto al valore impostato nel terzo argomento della riga di comando di "Read", sarà sollevato un errore "Fine del File" (End of File ).
Per evitare tale errore, bisognerà attribuire al terzo argomento un valore negativo. In tal caso si imposterà la lettura di un numero di dati-byte pari e non superiore a quello del valore del terzo argomento, e comunque non superiore al numero effettivo di dati-byte costituenti il file.

Read #file, variabile_stringa, -n

Pertanto, se ad esempio il file è composto da 6 dati-byte e il terzo argomento della riga di comando di "Read" è impostato al numero negativo -8, l'istruzione "Read" proverà a leggere 8 byte, ma avendo il suo terzo argomento con un valore negativo, ed essendo 6 i byte totali effettivamente leggibili, si fermerà all'ultimo byte leggibile, ossia il sesto (indice 5); quindi non eccedente la fine del file.

Usando il ciclo "While...Wend"

Se si intende leggere un byte per volta si utilizzerà anche un ciclo "While...Wend":

Public Sub Main()

 Dim s As String

 fl = Open "/percorso/del/file" For Read

 While Not Eof(fl)
   Read #fl, s, 1
   Print s;
 Wend

 fl.Close

End

Leggere uno specifico byte all'interno del file o dello stream

Se invece si intende effettuare la lettura cominciando da uno specifico byte all'interno del file, si dovrà usare anche la funzione "Seek".
In questo modo il puntatore interno del file si sposterà sul byte-dato di indice indicato nel secondo elemento sintattico della funzione Seek.

Public Sub Main()

 Dim fl As File
 Dim b As Byte
  
 fl = Open "/percorso/del/file" For Read
  
' Si scelge di leggere il valore del 4° byte (indice 3) del file:
 Seek #fl, 3

' Legge il valore del byte puntato da "Seek":
 Read #fl, b
  
 Print b
  
' Chiude il file:
 fl.Close
  
End

Leggere un file con READ e salvarne i dati in una Struttura

E' possibile leggere un file e salvarne i dati direttamente e in un solo momento in una "Struttura" adeguatamente costruita. ^{[Nota 2]}
Si adopererà la sintassi:

variabile_struttura Read #file As Nome_della_Struttura

Mostriamo un esempio, nel quale in un file sono contenuti i dati dei seguenti tipi: uno Short, un Integer e un Long.
Pertanto la lettura del file e la successiva scrittura dei dati nella Struttura avverà così:

Public Struct STRUTTURA
  s As Short
  i As Integer
  l As Long
End Struct


Public Sub Main()
 
 Dim fl As File
 Dim vst As STRUTTURA
 
 fl = Open "/percorso/del/file/da/leggere" For Read
 
 vst = Read #fl As STRUTTURA
 
' Effettua la verifica:
 Print vst.s, vst.i, vst.l
 
 fl.Close
 
End

Leggere da un file dati e assegnarli a un membro di tipo array

Va ricordato che, per assegnare dati - letti da un file - a un membro array di una Struttura, non è possibile utilizzare come membro un array nativo di Gambas:

Public Struct STRUTTURA
  ...
' Senza numero di elementi dichiarati:
 membro As Integer[]   Errore !
' oppure con numero di elementi dichiarati:
 membro As Integer[16] Errore !
  ...
End Struct

Bisogna invece usare gli array "annidati":

Public Struct STRUTTURA
  ...
 membro[16] As Integer  Corretto !
  ...
End Struct

Note

[1] Da notare che:

• in una istruzione READ #varFile, variabile, noi leggiamo il valore contenuto in "#varFile" e lo scriviamo in "variabile" (scriviamo, cioè, in "variabile" il valore presente in "varFile";
• in una istruzione WRITE #varFile, variabile, noi leggiamo il valore contenuto in "variabile" e lo scriviamo in "#varFile" (scriviamo, cioè, in "varFile" il valore presente in "variabile").

[2] Vedere anche questa analoga pagina della wiki: Assegnare direttamente i valori di dimensione conosciuta, letti da un file, ad una Struttura

Riferimenti

• https://gambaswiki.org/wiki/lang/read?l=it