Differenze tra le versioni di "Spostare oggetti con il mouse all'interno di un contenitore mediante Drag & Drop"

Versione delle 08:46, 14 giu 2023

Di seguito abbiamo due paragrafi per mostrare rispettivamente come spostare uno e due o più oggetti oggetti all'interno di un contenitore mediante l'uso del Drag 'n Drop.

Otterremo lo spostamento concreto ed effettivo dell'oggetto sfruttando le Proprietà ".X" e ".Y" della Classe Drag.

Spostare un solo Oggetto

L'esempio pratico, che mostriamo di seguito, prevede la presenza di un Button all'interno di un contenitore Genitore Panel. Tale Button verrà spostato all'interno del suo Contenitore Genitore mediante gli Eventi del Drag 'n Drop:

Public Sub Form_Open()

' Attiviamo la capacità del contenitore "Panel1" di ricevere con il "_Drop()" il testo trascinato:
 Panel1.Drop = True
     
End

Public Sub Button1_MouseDrag()

' Per poter trascinare l'oggetto "Button1", dobbiamo almeno fittiziamente trascinare un elemento che faccia riferimento ad una falsa stringa:
 Button1.Drag("")

End

Public Sub Panel1_DragMove()

' L'oggetto "Button1" - durante lo spostamento del mouse nel Contenitore "Panel1" - assume le coordinate del mouse medesimo:
 With Button1
   .X = Drag.X
   .Y = Drag.Y
' Affinché l'Oggetto "Button1" dopo lo spostamento nel Contenitore "Panel1" continui a funzionare regolarmente, bisogna attribuirgli il "Panel" quale suo nuovo "Genitore" Contenitore:
   .Reparent(Last)
 End With
  
End

Spostare un Oggetto facendo restare il puntatore del mouse nel punto dell'Oggetto dove si è cliccato

Durante lo spostamento di un Oggetto grafico può essere utile che il puntatore del mouse resti nel punto dell'Oggetto ove si è cliccato.

Mostriamo un possibile codice, nel quale si porrà sul Form un Panel, e al di sopra del Panel si porrà una Label:

Private x As Short
Private y As Short


Public Sub Form_Open()
 
 Label1.Background = Color.Red

 Panel1.Drop = True
    
End

Public Sub Label1_MouseDown()
 
 x = Mouse.X
 y = Mouse.Y
  
End

Public Sub Label1_MouseDrag()
 
 Label1.Drag("")
  
End

Public Sub Panel1_DragMove()

' Fa sì che durante lo spostamento della "Label" il puntatore del mouse resti nel punto della "Label" ove si è cliccato:
 With Label1
   .X = Drag.X - x
   .Y = Drag.Y - y
 End With
   
End

Spostare un Oggetto grafico fra molti

Nell'esempio che segue saranno creati dinamicamente più Button, che potranno essere spostati liberamente dall'utente.

Private Panel1 As Panel
Private bt As Button


Public Sub Form_Open()

 With Panel1 = New Panel(Me) As "Panel1"
   .X = 0
   .Y = 0
   .W = Me.W
   .H = Me.H
   .Background = Color.Lighter(Color.Yellow)
 End With
 For b As Byte = 1 To 10
   With bt = New Button(Panel1) As "Tasto"
     .W = 20.
     .H = 20
     .X = 10 * (b + b)
     .Y = 10 * b
     .Name = CStr(b)
     .Text = CStr(b)
     .Background = Color.Orange
   End With
 Next

 Panel1.Drop = True

End

Public Sub Tasto_MouseDrag()

 bt = Last

 Last.Drag("")

End

Public Sub Panel1_DragMove()

 With bt
   .X = Drag.X
   .Y = Drag.Y
 End With

End

Public Sub Tasto_MouseDown()

 Me.Title = "Premuto tasto n. " & Last.Name

End