Simulare il tasto premuto del mouse usando le funzioni esterne del API di X11

Da Gambas-it.org - Wikipedia.

La simulazione del tasto sinistro premuto del mouse (ossia generare un "_MouseDown()" e "_MouseUp()" o un "_Click()" automaticamente senza l'intervento manuale dell'utente) su un Controllo grafico o comunque su una qualsiasi finestra/superficie (desktop compreso), è un Evento a volte richiesto dai programmatori, ma di difficilissima realizzazione in Gambas.

Una soluzione può essere il richiamo diretto - mediante l'istruzione "Extern" - e indiretto - mediante una libreria esterna appositamente realizzata - di alcune funzioni esterne del sistema grafico X11, e contenute in particolare nella libreria condivisa: "libX11.so.6.4.0 ".

Mostriamo un semplice esempio, nel quale - simulando la pressione sul tasto sinistro del mouse - si cliccherà automaticamente su un Button posto sul Form.

Private Button1 As Button

Library "libX11:6.4.0"

' Display *XOpenDisplay(char *display_name)
' Opens a connection to the X server that controls a display.
Private Extern XOpenDisplay(display_name As Pointer) As Pointer

' int XFlush(Display *display)
' Flushes the output buffer.
Private Extern XFlush(display As Pointer)

' int XCloseDisplay(Display *display)
' Closes the connection to the X server for the display specified in the Display structure and destroys all windows.
Private Extern XCloseDisplay(display As Pointer) As Integer

 ' void XButtonClick(Display * dpy, unsigned int button, Bool is_press, unsigned long delay)
Private Extern XButtonClick(dpy As Pointer, button As Integer, is_press As Boolean, delay As Long) In "/tmp/mouse"


Public Sub _new()

 With Me
   .X = 100
   .Y = 150
 End With
 With Button1 = New Button(Me) As "Button1"
   .X = 70
   .Y = 120
   .W = 100
   .H = 50
 End With

 Me.Show

' Va a generare la libreria esterna condivisa ad hoc per la gestione di una particolarissima funzione di X11:
 creaso()

' Le istruzioni interne al ciclo assicurano che il puntatore del mouse si venga a trovare sul "Button" posto sul "Form":
 Dim g As Single
 Repeat 
   g += 0.1
' Sposta il puntatore del mouse sul "Button" posto sul "Form":
   Mouse.Move(Button1.ScreenX + 20, Button1.ScreenY + (Button1.H * g))
   Wait 0.1
 Until Mouse.Inside(Button1)
 
 Dim dsp As Pointer = XOpenDisplay(0)
 If dsp == 0 Then Error.Raise("Errore !")
 XButtonClick(dsp, 1, CByte(True), 500)
 XFlush(dsp)
 Wait 0.7
 XButtonClick(dsp, 1, CByte(False), 0)
 XFlush(dsp)

 XCloseDisplay(dsp)
' Assicura che il Puntatore non punti a un indirizzo rilevante di memoria:
 dsp = 0
  
End


Private Procedure Creaso()
 
 File.Save("/tmp/mouse.c", "#include <X11/Xlib.h>\n" &
                           "#include <X11/extensions/XTest.h>\n" &
                           "void XButtonClick(Display * disp, unsigned int xbutton, Bool press, unsigned long rit) {\n"
                           "  XTestFakeButtonEvent(disp, xbutton, press, rit);\n}")

 Shell "gcc -o /tmp/mouse.so /tmp/mouse.c -shared -lX11 -lXtst" Wait

End


Public Sub Button1_Click()

 Print "Tasto premuto !"

End

In questa variante del codice precedente si cliccherà automaticamente prima sul Button posto sul Form e successivamente sul tastino "X" di chiusura - posto nell'angolo alto a destra del Form medesimo:

Private Button1 As Button

Library "libX11:6.4.0"

' Display *XOpenDisplay(char *display_name)
' Opens a connection to the X server that controls a display.
Private Extern XOpenDisplay(display_name As Pointer) As Pointer

' int XFlush(Display *display)
' Flushes the output buffer.
Private Extern XFlush(display As Pointer)

' int XCloseDisplay(Display *display)
' Closes the connection to the X server for the display specified in the Display structure and destroys all windows.
Private Extern XCloseDisplay(display As Pointer) As Integer

' void XButtonClick(Display * dpy, unsigned int button, Bool is_press, unsigned long delay)
Private Extern XButtonClick(display As Pointer, xbutton As Integer, is_press As Boolean, delay As Long) In "/tmp/mouse"


Public Sub _new()

 With Me
   .X = 100
   .Y = 150
 End With
 With Button1 = New Button(Me) As "Button1"
   .X = 70
   .Y = 120
   .W = 100
   .H = 50
 End With

 Me.Show

' Va a generare la libreria esterna condivisa ad hoc per la gestione di una particolarissima funzione di X11:
 creaso()

' Le istruzioni interne al ciclo assicurano che il puntatore del mouse si venga a trovare sul "Button" posto sul "Form":
 Dim g As Single
 Repeat 
   g += 0.1
' Sposta il puntatore del mouse sul "Button" posto sul "Form":
   Mouse.Move(Button1.ScreenX + 20, Button1.ScreenY + (Button1.H * g))
   Wait 0.1
 Until Mouse.Inside(Button1)

 TastoPremuto()

End


Private Procedure Creaso()
 
 File.Save("/tmp/mouse.c", "#include <X11/Xlib.h>\n" &
                           "#include <X11/extensions/XTest.h>\n" &
                           "void XButtonClick(Display * disp, unsigned int xbutton, Bool press, unsigned long rit) {\n"
                           "  XTestFakeButtonEvent(disp, xbutton, press, rit);\n}")
                           
 Shell "gcc -o /tmp/mouse.so /tmp/mouse.c -shared -lX11 -lXtst" Wait

End


Private Procedure TastoPremuto()

 Dim dsp As Pointer = XOpenDisplay(0)
 If dsp == 0 Then Error.Raise("Errore !")
 XButtonClick(dsp, 1, CByte(True), 500)
 XFlush(dsp)
 Wait 0.7
 XButtonClick(dsp, 1, CByte(False), 0)
 XFlush(dsp)

 XCloseDisplay(dsp)
' Assicura che il Puntatore non punti a un indirizzo rilevante di memoria:
 dsp = 0

End


Public Sub Button1_Click()

 Print "Tasto premuto !"

' Pone un'attesa di 1 secondo, per mostrare più chiaramente il successivo spostamento del puntatore del mouse:
 Wait 1

' Sposta il puntatore del mouse sul tastino "X" in alto a destra di chiusura del "Form":
 Mouse.Move(Me.ScreenX + Me.W - 12, Me.Y + 12)

 TastoPremuto()

End