Visualizza wikitesto di Scrivere una Funzione

Una '''Funzione''' <FONT Color=blue><SUP>[note:</sup></font> [[#Note|<SUP>1</sup>]] [[#Note|<SUP>2</sup>]] [[#Note|<SUP>3</sup>]] [[#Note|<SUP>4</sup>]] [[#Note|<SUP>5</sup>]]<FONT Color=blue><SUP>]</sup></font>  è una routine, chiamata da una routine principale, alla quale è delegato il compito di svolgere una serie di operazioni, e delle quali essa restituisce alla routine principale ''chiamante'' il risultato.

La Funzione è l'operazione attinente ad una fase del processo del programma.

Poiché una funzione deve eseguire ''un'' compito, si ritiene non opportuno scrivere una funzione per eseguire più istruzioni insieme. E' preferibile scrivere funzioni per singoli compiti ed una ulteriore funzione che svolga l'operazione complessa, invocando le funzioni precedenti.



=Definizione di una Funzione=
La funzione, creata dal programmatore, in Gambas è sostanzialmente definita come segue:
 [Public/Private] Function ''Nome_Funzione''( ''dichiarazione dei parametri, se previsti'' As ''tipo_passato ) As ''Tipo_ritornato''
   
   ''eventuali_dichiarazioni_di_tipi_di_variabili''
   
   ''istruzioni''
   
   Return ''valore_da_ritornare''
   
 End
La parola chiave ''Function'', che specifica e definisce una Funzione ''chiamata'', può essere preceduta dalla parola chiave ''Public'' o ''Private'' a seconda delle necessità di visibilità della Funzione medesima.

Una Funzione, per essere utilizzata dal processo del programma, deve essere invocata, chiamata da una specifica Funzione ''chiamante''. Tale Funzione ''chiamante'' deve avere un nome identificativo <SPAN Style="text-decoration:underline">identico</span> a quello della Funzione ''chiamata''.

Inoltre, <SPAN Style="text-decoration:underline">se è previsto</span> che la Funzione ''chiamante'' passi alla Funzione ''chiamata'' uno o più valori, affinché essi vengano processati dalle istruzioni contenute dalla Funzione ''chiamata'', detti valori pasati devono essere del tipo <SPAN Style="text-decoration:underline">identico</span> a quello dichiarato nella Funzione ''chiamata''. In tal senso i valori, passati dalla Funzione ''chiamante'' sono definiti " ''argomenti'' ", mentre i valori dichiarati - e quindi poi ricevuti - dalla Funzione ''chiamata'' sono definiti " ''parametri'' ".

La Funzione ''chiamata'' ritorna <SPAN Style="text-decoration:underline">sempre</span> un valore, che è il risultato delle operazioni svolte dalle istruzioni presenti nella Funzione. <SUP>&#091;[[#Note|Nota 6]]&#093;</sup>


Mostriamo di seguito un semplice esempio pratico con la modalità più comune di ritorno di valore:
 Public Sub Main()
 
  Dim i, rit As Integer
  
   i = 10
   
 <FONT Color=gray>' ''La seguente Funzione "chiamante" invoca la Funzione "chiamata" e le passa un valore come "argomento",''
 ' ''affinché sia processato, e dalla quale riceverà un valore come risultato di quel processo:''</font>
   rit = Calcolare(i)
   
   Print "Valore ritornato: "; i
   
 End
 
 
 <FONT Color=gray>' ''La seguente Funzione "chiamata" riceve un valore, come "parametro" dalla Funzione "chiamante".''
 ' ''Quindi lo elabora con le istruzioni da essa contenute, e lo restituisce alla Funzione "chiamante":''</font>
 Private Function Calcolare(valore As Integer) As Integer
  
  Dim n, r As Integer
  
   n = 100
   
   r = valore * n
   
   Return r
   
 End



=Passaggio dei dati ad una Funzione=
Nel paragrafo precedente abbiamo visto con la parola ''Return'' la modalità più frequente e più semplice per ritornare in Gambas un dato da una Funzione. Ma non è la sola modalità.

In Gambas la routine principale ''chiamante'' può passare attraverso i suoi argomenti uno o più valori alla Funzione chiamata. Il passaggio degli argomenti ad una Funzione può essere di tre tipi: <SUP>&#091;[[#Note|Nota 7]]&#093;</sup>
* per ''valore'';
* per ''indirizzo'';
* per ''riferimento''.


==Passaggio per ''valore''==
Il passaggio per ''valore'' è senz'altro la modalità più frequente di passare dei dati ad una Funzione chiamata.

Nel passaggio per "valore" viene - appunto - passato un valore o sotto forma di dato effettivo (ad esempio direttamente un dato numerico oppure indirettamente mediante una variabile - ad esempio di tipo Byte, Short, etc. - che contiene e dunque fornisce un valore.

Con il passaggio ''per valore'' viene effettuata una ''copia'' della variabile passata alla Funzione chiamata come argomento della routine principale chiamante. Inoltre, le modifiche alla variabile del parametro passato, effettuate nella Funzione chiamata, restano confinate nell'ambito locale di detta Funzione secondaria. Ciò significa che la variabile, passata come parametro dalla routine chiamante a quella chiamata, non vede modificarsi il suo valore, nonostante la sua copia abbia subito una modifica del proprio valore a seguito di una o più operazioni nella Funzione secondaria chiamata. La viariabile presente nella routine principale chiamante resta intatta, immodificata, qualunque cosa avvenga alla sua ''copia'' nella Funzione chiamata.
<BR>Se, dunque, non vi fosse ritorno di valore della varibile-copia, ora con valore modificato, alla routine principale chiamante, non sarebbe possibile utilizzare nella predetta routine chiamante le modifiche apportate dalle operazioni, alle quali la Funzione secondaria chiamata è stata preposta.


Mostriamo un semplice esempio:
 '''Public''' Sub Main() <FONT color=gray>' ''Routine principale''</font>
 
  Dim a, b, risultato_di_ritorno As Integer
 
   a = 2
   b = 3
 
 <FONT color=gray>' ''Chiama la Funzione, e le passa i due valori, affinché li elabori.''
 ' ''Alla fine la Funzione restituirà il risultato che riempirà la variabile integer "risultato_di_ritorno":</font>
   <FONT Color=#B22222>risultato_di_ritorno</font> = funzione_chiamata(<FONT color=blue>a</font>, <FONT color=blue>b</font>)
  
 <FONT color=gray>' ''Mostriamo il risultato in console:''</font>
   Print "Risultato di ritorno dalla funzione = "; risultato_di_ritorno
 
 '''End'''
 
 
 <FONT color=gray>' ''La funzione secondaria "Funzione_Chiamata" contiene il proprio nome ed i parametri come variabili dei valori passati dalla routine chiamante, e non prevede l'aggiunta della parola chiave "Sub".''
 ' ''Essa, poiché restituisce - in questo nostro esempio - un valore Integer, termina la propria dichiarazione con "As Integer" .''</font>
 '''Private Function''' Funzione_Chiamata(<FONT color=blue>aF As Integer</font>, <FONT color=blue>bF As Integer</font>) <FONT Color=#B22222>As Integer</font>
 
  Dim somma As Integer
 
 <FONT color=gray>' ''Non è necessario dichiarare le due variabili, poiché lo si è già fatto nei parametri della funzione:''</font>
   somma = <FONT color=blue>aF + bF</font>
 
 <FONT color=gray>' ''Viene restituito il risultato alla routine chiamante:''</font>
   <FONT Color=#B22222>Return somma</font>
  
 '''End'''

In console avremo coerentemente:
<BR>Risultato di ritorno dalla funzione = 5


===...e se la Funzione deve restituire due o più dati ?===
Se la Funzione deve restituire più di un dato non è possibile utilizzare l'istruzione ''Return'' con una variabile ordinaria, giacché essa restituisce un solo dato.

Per ottenere da una medesima Funzione due o più risultati (quindi <SPAN Style="text-decoration:underline">senza</span> dover utilizzare una variabile globale), possiamo utilizzare due modalità:
* uso di una variabile vettoriale o una ''Struttura'';
* il passaggio per ''indirizzo'' (vedi paragrafo successivo).

====Uso di un vettore come ritorno di una Funzione====
Mostriamo un esempio di una Funzione che ritorna per "valore" un duplice risultato mediante una variabile vettoriale:
 '''Public''' Sub Main()
 
  Dim a, b As Integer
  Dim risultato_di_ritorno As Integer[]
  
  a = 2
  b = 3
 
 <FONT color=gray>' ''Chiama la Funzione, e le passa i due valori, affinché li elabori. Alla fine la Funzione restituirà il risultato che riempirà la variabile vettoriale integer[] chiamata "risultato_di_ritorno":''</font>
  risultato_di_ritorno = Funzione_Chiamata(a, b)
 
 <FONT color=gray>' ''Mostriamo il primo risultato (la somma) in console:''</font>
  Print "Risultato (somma) di ritorno dalla funzione = "; risultato_di_ritorno[0]
 
 <FONT color=gray>' ''Mostriamo il secondo risultato (la differenza) in console:''</font>
  Print "Risultato (differenza) di ritorno dalla funzione = "; risultato_di_ritorno[1]
 
 '''End'''
 
 
 <FONT color=gray>' ''La routine Funzione, poiché restituisce - per "''Valore''" - un valore vettore Integer[], termina la propria dichiarazione con: As Integer[].''</font>
 '''Public Function''' Funzione_Chiamata(aF As Integer, bF As Integer) As Integer[]
 
  Dim somma, differenza As Integer
  Dim doppiorisultato As New Integer[]
 
  somma = aF + bF
  differenza = bF - aF
 
 <FONT color=gray>' ''Nel primo campo dell'array inseriamo il valore contenuto dalla variabile Integer "somma":''</font>
  doppiorisultato.Add(somma)
 
 <FONT color=gray>' ''Nel secondo campo dell'array inseriamo il valore contenuto dalla variabile Integer "differenza":''</font>
  doppiorisultato.Add(differenza)
 
 <FONT color=gray>' ''Dunque ora la variabile Integer[] "doppiorisultato" contiene due valori.''
 ' ''Tale duplice contenuto di questa variabile Integer[] viene restituito alla routine principale chiamante:''</font>
  Return doppiorisultato
 
 '''End'''

In console avremo coerentemente:
<BR>Risultato (somma) di ritorno dalla funzione = 5
<BR>Risultato (differenza) di ritorno dalla funzione = 1



==Passaggio per ''indirizzo''==
Il passaggio per ''indirizzo'' prevede che la routine principale chiamante passi come propri argomenti alla Funzione chiamata gli ''indirizzi di memoria'' delle variabili della routine chiamante contenenti i valori che dovranno essere gestiti dalle istruzioni della Funzione chiamata. <SUP>&#91;[[#Note|Nota 8]]&#93;</sup>

Nel passaggio per "indirizzo" viene - appunto - passato l'indirizzo di memoria ove è memorizzato un valore oppure un Oggetto.

Il passaggio per ''Indirizzo'' di un argomento può avvenire mediante:
* i Vettori;
* la variabile di tipo Puntatore;
* le Strutture;
* le variabili identificatrici di un Oggetto, quale istanza di una Classe.
Ciò in quanto le rispettive variabili contengono gli ''indirizzi'' alle aree di memoria da esse puntate ove sono memorizzati i vari dati.
<BR>Quando si deve passare l'indirizzo di memoria di una variabile, diversa da un ''Vettore'' e da una ''Struttura'', si userà la funzione ''VarPtr( )'', altrimenti si passerà un Puntatore ad un'area di memoria opportunamente allocata con al funzione ''Alloc( )''.

La particolarità del passaggio degli argomenti per ''indirizzo'' è che tale modalità di passaggio ci consente di eliminare l'istruzione ''Return'', e di ritornare, così, il valore dalla Funzione chiamata alla routine principale chiamante attraverso i parametri medesimi della Funzione. Inoltre, esso non determina la creazione di una ''copia'' della variabile passata (come invece avviene per il passaggio per ''valore'').
<BR>Avere un riferimento all'oggetto è molto utile in fase di passaggio tramite parametri tra un Metodo e l'altro. La modifica dell'oggetto fa sì che venga mantenuta in uscita dal Metodo, eliminando così l'obbligo del ritorno di un valore.

E' appena il caso di ricordare che il passaggio di valori "''per Indirizzo''" a una sotto-procedura/funzione, non crea una copia dell'Oggetto, o comunque del tipo, passato, come avviene invece nel passaggio "''per Valore''", ove si va ad occupare un'altra area di memoria (per generare la copia) di dimensioni pari a quella occupata dall'Oggetto (o dal tipo di valore) passato.
<BR>Va da sé che con il passaggio "''per Valore''", avendo due copie uguali, avremo due indirizzi di memoria che si riferiscono ovviamente a due aree di memoria riservate automaticamente di uguale dimensione, ...e quindi un consumo doppio delle risorse (ossia della memoria necessaria per il passaggio dei dati).
<BR>Il passaggio "''per Indirizzo''" fa in modo che la modifica avvenga direttamente all'indirizzo di memoria dell'Oggetto (o del tipo di valore) passato evitando così la creazione di una copia e l'occupazione di altra memoria per il medesimo dato da passare.

====Semplici esempi pratici====
Mostriamo un esempio pratico con un ''Vettore'':
 '''Public''' Sub Main()
  
  Dim vett As New Integer[4]
  Dim i As Integer
  
   Funzione(vett)
   
   For Each i In vett
     Print i
   Next
   
 '''End'''
 
 
 '''Private''' Function Funzione(ii As Integer[])
  
  Dim c As Integer
  
    For c = 0 To ii.Max
      ii[c] = c + 1000
    Next
  
 '''End'''


Ora un esempio con una ''Struttura'':
 Public Struct STRUTTURA
   b As Byte
   s As Short
   i As Integer
   l As Long
 End Struct
 
 
 '''Public''' Sub Main()
  
  Dim sr As New STRUTTURA
  
   Funzione(sr)
   
   With sr
     Print .b
     Print .s
     Print .i
     Print .l
   End With
   
 '''End'''
 
 
 '''Private''' Function Funzione(tr As STRUTTURA)
  
  With tr
    .b = 100
    .s = 1000
    .i = 100000
    .l = 10000000
  End With
  
 '''End'''


Quindi un paio di esempi nei quali la funzione passa l'<I>indirizzo di memoria</i> di una variabile dichiarata. Per scrivere nella variabile, ricevuta come parametro di tipo ''Puntatore'' della Funzione chiamata, il risultato finale delle operazioni compiute in tale Funzione, bisognerà ovviamente utilizzare i ''Memory Stream'' unitamente alla funzione ''Write''.

Mostriamo un esempio, nel quale la funzione passa l'<I>indirizzo di memoria</i> di una variabile dichiarata di tipo ''Intero Lungo'':
 '''Public''' Sub Main()
  
  Dim num As Long
  
   Funzione(VarPtr(num))
    
   Print num
   
 '''End'''
 
 
 '''Private''' Function Funzione(p As Pointer)
  
  Dim st As Stream
  
   st = Memory p For Write
   Write #st, 1234567890 As Long
   st.Close
  
 '''End'''
Dello stesso tipo appena visto, il seguente esempio, ove avviene lo scambio di valori fra due variabili (''swapping''):
 '''Public''' Sub Main()
  
  Dim i1, i2 As Integer
  
   i1 = 1000
   i2 = 2000
    
   Scambio(VarPtr(i1), VarPtr(i2))
    
   Print i1, i2
   
 '''End'''
 
 
 '''Private''' Function Scambio(x As Pointer, y As Pointer)
  
  Dim z As Integer
  Dim st As Stream
     
   z = Int@(x)
    
   st = Memory x For Write
   Write #st, Int@(y) As Integer
   st.Close
    
   st = Memory y For Write
   Write #st, z As Integer
   st.Close
   
 '''End'''


Nei seguenti due esempi, invece, sarà passata una variabile di tipo ''Puntatore'' che punta ad un'area di memoria appositamente riservata.
<BR>In questo esempio l'area di memoria conterrà valori numerici generici:
 '''Public''' Sub Main()
  
  Dim ptr As Pointer
  Dim c As Integer
  
   ptr = Alloc(SizeOf(gb.Byte), 8)
  
   Funzione(ptr)
    
   For c = 0 To 7
     Print Byte@(ptr + c)
   Next
   
   Free(ptr)
   ptr = 0
   
 '''End'''
 
 
 '''Private''' Function Funzione(p As Pointer)
  
  Dim st As Stream
  Dim b As Byte
     
   st = Memory p For Write
   For b = 1 To 8
     Write #st, b * 10 As Byte
   Next
   st.Close
  
 '''End'''

In quest'altro esempio sarà passata un'area di memoria contenente i valori prettamente attinenti a caratteri stringa:
 '''Public''' Sub Main()
 
  Dim p As Pointer
  
   p = Alloc("abcde")
   
   Funzione(p)
    
   Print String@(p)
      
   Free(p)
   p = 0
 
 '''End'''
 
 
 '''Private''' Function Funzione(po As Pointer)
  
  Dim st As Stream
    
   st = Memory po For Write
   
   Write #st, 70 As Byte
   
   st.Close
  
 '''End'''


====Ritorno di più dati====
Come già accennato, la modalità del passaggio per ''indirizzo'' ci consente di ritornare alla routine chiamante anche più dati.

Mostriamo un esempio pratico, nel quale vengono ritornati due dati attraverso i parametri della Funzione chiamata e di quella chiamante:
 '''Public''' Sub Main()
 
  Dim dividendo, divisore As Integer
  Dim p1, p2 As Pointer
 
   Print "Scrivere i valori del dividendo e del divisore."
   Input dividendo
   Input divisore
 
   p1 = VarPtr(dividendo)
   p2 = VarPtr(divisore)
 
   Funzione_Chiamata(p1, p2)
 
   Print "Quoziente: "; Int@(p1)
   Print "Resto: "; Int@(p2)
 
 '''End'''
 
 
 '''Public''' Function division(divid As Pointer, divis As Pointer)
 
  Dim i1, i2, ris As Integer
  Dim st As Stream
  
   i1 = Int@(divid)
   i2 = Int@(divis)
   ris = i1 / i2
 
   st = Memory divid For Write
   Write #st, ris As Integer
   st.Close
    
   ris = i1 Mod i2
 
   st = Memory divis For Write
   Write #st, ris As Integer
   st.Close
 
 '''End'''


===Ritorno di dati per "''Indirizzo''" senza utilizzo come argomento di un esplicito ''Puntatore''===
Abbiamo visto nel paragrafo appena precedente che il ritorno di un dato attraverso i parametri (o argomenti) della Funzione prevedeva che il parametro (o i parametri, nel caso si intenda far ritornare più dati) deve essere dichiarato come tipo ''Puntatore'', dato che si tratta di passaggio dell'indirizzo di memoria della variabile, presente nella routine principale, contenente il dato da gestire nella Funzione secondaria chiamata.

Qualora il tipo di argomenti siano una ''Struttura'' oppure un ''vettore'', non v'è necessità che i parametri, passati alla Funzione chiamata, siano di tipo ''Puntatore''.

Mostriamo due esempi pratici.
 Public Struct STRUTTURA
   b As Byte
   s As Short
   i As Integer
 End Struct
 
 
 '''Public''' Sub Main()
 
  Dim st As New STRUTTURA
  
   With st
     .b = 99
     .s = 9999
     .i = 999999
   End With
  
  
   Funzione_Chiamata(st)
    
   With st
     Print .b
     Print .s
     Print .i
   End With
 
 '''End'''
 
 
 '''Private''' Function Funzione_Chiamata(n As STRUTTURA)
  
   With n
     .b += 99
     .s += 9999
     .i += 999999
   End With
  
 '''End'''

 
 '''Public''' Sub Main()
 
  Dim ss As String[] = ["a", "b", "c"]
   
   Print ss.Count
    
   Prova(ss)
    
   Print ss.Count
 
 '''End'''
 
  
 '''Private''' Function Prova(vett As String[])
 
  vett.Remove(1)
   
 '''End'''



==Passaggio per ''Riferimento''==
Il passaggio per ''Riferimento'' in Gambas prevede <SPAN Style="text-decoration:underline">sia</span> nella Funzione chiamante <SPAN Style="text-decoration:underline">sia</span> nella Funzione chiamata l'uso della parola chiave '''''ByRef''''' prima dell'argomento da passare.

Questa modalità è una risorsa specifica e all'uopo dedicata di Gambas per passare per ''per indirizzo'' variabili che non siano già di per sé comunque dei ''Puntatori''. Infatti essa è nella sostanza identica a quella "''per Indirizzo''": non necessita dell'uso dell'istruzione ''Return'' al termine della Funzione chiamata.
<BR>Come già detto nel paragrafo relativo al passaggio di argomenti ''per Indirizzo'', avere un riferimento all'oggetto è molto utile in fase di passaggio tramite parametri tra un Metodo e l'altro. La modifica dell'oggetto fa sì che venga mantenuta in uscita dal Metodo, eliminando così l'obbligo del ritorno di un valore.

Mostriamo un esempio:
 '''Public''' Sub Main()
 
 Dim a, b As Integer
 
  a = 2
  b = 3
 
   Funzione_Chiamata(<FONT Color=#B22222>ByRef</font> a, b)
 
   Print "Risultato di ritorno dalla funzione = "; a
 
 '''End'''
 
 
 '''Private''' Function Funzione_Chiamata(<FONT Color=#B22222>ByRef</font> aRif As Integer, bI As Integer)
 
  Dim somma As Integer
  
 <FONT color=gray>' ''Si effettua l'operazione fra i due argomenti, ed il risultato viene restituito attraverso il parametro individuato con "ByRef":''</font>
   aRif = aRif * bI
 
 '''End'''


====Ritorno di più dati====
Anche con il passaggio per ''Riferimento'' mediante la parola chiave "''ByRef''" è possibile ritornare alla funzione chiamante due o più dati. Per fare ciò si dovrà porre la parola chiave ''ByRef'' su due o più argomenti da passare delle Funzioni chiamante e chiamata.



=Scrivere ed invocare una Funzione in un Modulo=
La scrittura e la successiva invocazione di una Funzione in un ''Modulo'' segue la procedura normale.


Facciamo un semplissimo esempio.

Nella Classe principale avremo il seguente codice:
 '''Public''' Sub Form_Open()  
  
 Dim by As Byte  
   
 <FONT color=gray>' ''Invochiamo la funzione nel Modulo e le passiamo un valore di tipo Byte (in questo esempio: 6 ).''
 ' ''Essa, a sua volta, ci passerà un valore che inseriremo nella variabile "by":''</font>
    by = Module1.funzioneNelModulo(6)
  
    Print by
  
 '''End'''


Nel Modulo avremo:
 '''Public''' Function funzioneNelModulo(a As Byte) As Byte  <FONT color=gray>' ''Riceve dalla routine chiamante un valore di tipo "Byte", ed un valore di tipo "Byte" a sua volta restituirà''</font>  
   
  Dim b As Byte  
   
   b = 2  
   
 <FONT color=gray>' ''La Funzione effettua l'operazione per la quale è stata concepita:''</font>
     b = b * a  
   
 <FONT color=gray>' ''Restituisce, quindi, alla routine chiamante, presente nella Classe principale, il risultato dell'operazione:''</font>
     Return b
   
 '''End'''




=Note=
[1] «''La "funzione" di una cosa è ciò che la sola cosa può compiere.''» (Platone, ''La Repubblica'')

[2] La Funzione è un complesso di operazioni coordinate, tale da configurarsi in sé come una ''norma''.

[3] La Funzione " ''offre un metodo conveniente per racchiudere una parte di programma in grado di eseguire un compito specifico, in modo che sia riutilizzabile senza preoccuparsi della sua implementazione.'' " (Kernighan B. W. - Ritchie D. M., ''Il linguaggio C'' - seconda edizione, Pearson edizioni) 

[4] Si rinvia anche a ''Wikipedia'' per una definizione più ampia della ''[http://it.wikipedia.org/wiki/Funzione_%28informatica%29 Funzione]''.

[5] Possiamo distinguere quattro tipi di ''Funzioni'':
* native ed autonome. Si tratta di quelle Funzione che sussistono di per sé all'interno di Gambas, avendo così una ''dignità'' propria (ad esempio: ''Alloc()'', ''SizeOf()'', ''Max()'' e così via).
* ''metodi'' di Classi Gambas. Si tratta di quelle Funzioni di Gambas che non sono ''autonome'', ma esistono in quanto risorse tipiche di una Classe. Tali Funzioni (''Metodi'') possono essere utilizzati <SPAN Style="text-decoration:underline">solo se richiamate attraverso un Oggetto</span> di una Classe. Esempi di tali Funzioni: ''Object.<FONT Color=#B22222>SizeOf()</font>'', ''Button1.<FONT Color=#B22222>Move()</font>'', ''vettore.<FONT Color=#B22222>Push()</font>'', ''Paint.<FONT Color=#B22222>DrawImage()</font>'' e così via.
* Funzioni scritte dal programmatore (oggetto della presente pagina): sono appunto specifiche Funzioni, scritte dal programmatore, per assolvere ad un particolare compito che si esaurisce con l'applicazione, nella quale la Funzione è stata appositamente creata.
* Funzioni esterne. Tali funzioni <SPAN Style="text-decoration:underline">non</span> appartengono al linguaggio Gambas, bensì a librerie esterne di funzioni. Tali funzioni esterne possono essere richiamate e gestite da Gambas mediante la parola [[Extern:_richiamare_funzioni_esterne_a_Gambas|Extern]].

[6] Anche se non è una regola rigida che possa dare errore, in Gambas una Funzione ''restituisce'' sempre un valore alla Funzione ''chiamante''; pertanto si preferisce definirla con la parola chiave ''Function'' (preceduta dalla parola chiave ''Public'' o ''Private'' a seconda ovviamente delle necessità), rispetto ad una routine che ''non'' restituisce alcun valore, e che - in tal caso - verrà definita con la parola chiave ''Sub'' o ''Procedure'' (preceduta dalla parola chiave ''Public'' o ''Private'' a seconda ovviamente delle necessità),.
<BR>Ricapitolando:
<BR>- se la subroutine chiamata restituisce un valore alla Funzione ''chiamante'', allora la subroutine chiamata sarà considerata una ''Funzione'' in senso stretto, e verrà dichiarata formalmente con la parola chiave ''Function'':
 Public/Private '''Function''' Nome_Funzione(parametro As tipo_valore, ......) As tipo_valore
 
   .....
   .....
   
   Return valore
   
 End

- se invece la subroutine chiamata <SPAN Style="text-decoration:underline">non</span> restituisce un valore alla Funzione ''chiamante'', allora la subroutine chiamata sarà considerata una mera ''Procedura'', e si preferisce dichiararla formalmente con la parola chiave ''Procedure'' o con ''Sub'':
 Public/Private '''Procedure''' Nome_Procedura(parametro As tipo_valore, ......)
 
   .....
   .....
   
 End

[7] In Gambas elementi complessi come gli Oggetti vengono sempre passati come Riferimento, ovvero l'indirizzo di memoria in cui si trovano. Riguardo invece alle normali variabili di tipi base (Byte, Short, Integer/String/Long ecc.) queste non sono Oggetti ma "valori" ben precisi, che vengono passati come "Valore", e non come locazione di memoria. Questa differenza implica che, per quanto riguarda gli Oggetti, ogni modifica al suo contenuto viene mantenuta, mentre per le variabili, dato che ne viene passata una copia del valore, queste vengono perse all'uscita della stessa funzione che le gestisce.
<BR>Il concetto di parametro passato "per Riferimento" (ByRif) in Gambas, fa sì che la funzione prende in ingresso l'indirizzo di memoria in cui è depositato il valore, e non ne crea una copia. Ciò consente, come per gli Oggetti, di ritrovarsi la variabile di base modificata anche dopo l'uscita dalla funzione. 

[8] Al riguardo vedere anche la seguente pagina della WIKI: http://www.gambas-it.org/wiki/index.php?title=Passaggio_di_un_argomento_per_%27indirizzo%27_ad_una_Funzione