Modificare ad un file WAV la frequenza di campionamento e il numero di canali usando una linea di pipeline con la funzione 'gst parse launch()'

La funzione esterna gst_parse_launch() della libreria GStreamer consente di costruire e gestire in modo semplice una pipeline GStreamer. La riga della pipeline gestita dalla funzione esterna gst_parse_launch() è un insieme di elementi separati da punti esclamativi (!). Le proprietà possono essere aggiunte agli elementi, sotto forma di: proprietà = valore.

Sarà necessario avere installata nel sistema e richiamare nell'applicazione Gambas la libreria dinamica condivisa: "libgstreamer-1.0"

Mostriamo un esempio pratico, nel quale ad un file WAV la frequenza di campionamento verrà ridotta a 8000 hertz ed il numero dei canali ad 1 (mono):

Library "libgstreamer-1.0"

Private Enum GST_STATE_VOID_PENDING = 0, GST_STATE_NULL, GST_STATE_READY, GST_STATE_PAUSED, GST_STATE_PLAYING
Private Const GST_FORMAT_TIME As Integer = 3

' gst_init (int *argc, char **argv[])
' Initializes the GStreamer library, setting up internal path lists, registering built-in elements, and loading standard plugins.
Private Extern gst_init(argc As Pointer, argv As Pointer)

' GstElement * gst_parse_launch (const gchar *pipeline_description, GError **error)
' Create a new pipeline based on command line syntax.
Private Extern gst_parse_launch(description As String, GError As Pointer) As Pointer

' GstStateChangeReturn gst_element_set_state(GstElement *element, GstState state)
' Sets the state of the element.
Private Extern gst_element_set_state(gstelement As Pointer, state As Integer) As Integer

' gboolean gst_element_query_duration(GstElement *element, GstFormat format, gint64 *duration)
' Queries an element for the total stream duration in nanoseconds.
Private Extern gst_element_query_duration(gselement As Pointer, formatI As Integer, duration As Pointer) As Boolean
 
' gboolean gst_element_query_position (GstElement *element, GstFormat format, gint64 *cur)
' Queries an element for the stream position in nanoseconds.
Private Extern gst_element_query_position(gstelement As Pointer, gstformat As Pointer, cur As Pointer) As Boolean

' void gst_object_unref(gpointer object)
' Decrements the reference count on object.
Private Extern gst_object_unref(gobject As Pointer)


Public Sub Main()
 
 Dim audio As Pointer
 Dim dur, pos As Long
     
  gst_init(0, 0)
  
  audio = gst_parse_launch("uridecodebin uri=file:///percorso/del/file/audio.wav ! audioresample ! audioconvert ! audio/x-raw, rate=8000, channels=1 ! wavenc ! filesink location=/percorso/del/nuovo/file.wav", 0)
       
' Avviamo la conversione audio:
  gst_element_set_state(audio, GST_STATE_PLAYING)
  
  While True
    gst_element_query_position(audio, GST_FORMAT_TIME, VarPtr(pos))
    gst_element_query_duration(audio, GST_FORMAT_TIME, VarPtr(dur))
    If (pos > 0) And (pos >= dur) Then Break
    Write #File.Out, "\rTempo: " & Date(0, 0, 0, 0, 0, 0, pos / 1000000)
  Wend
  
  gst_element_set_state(audio, GST_STATE_NULL)
  gst_object_unref(audio)
   
  Quit
   
End

Riferimenti

• http://docs.gstreamer.com/display/GstSDK/gst-launch
• http://gstreamer.freedesktop.org/
• http://gstreamer.com/