Versione attuale delle 05:49, 20 nov 2023

E' possibile modificare i colori dei pixel di un'immagine utilizzando la proprietà .Data della Classe Image ed i Memory Stream. ^{[nota 1]}

La Proprietà ".Data" della Classe Image ritorna un Puntatore ai dati della variabile di tipo Image. Si potrà, quindi, per mezzo dei Memory Stream leggere all'interno dell'area puntata dal predetto Puntatore.
Sarà possibile altresì scrivervi modificando quindi il colore di uno o di più pixel dell'immagine.

Esempi

Nell'esempio che segue abbiamo una semplice immagine formata da 8x8 pixel tutti di colore giallo, che saranno mostrati in una "PictureBox" all'apertura del "Form". Cliccando sul tasto (da porre anch'esso sul "Form") si cambierà in rosso il colore del secondo pixel (che corrisponde graficamente al secondo pixel da sinistra della prima fila in alto dell'immagine).

Private im As Image


Public Sub Form_Open()
 
 im = New Image(8, 8, Color.Yellow, Image.Standard)
  
 With PictureBox1
   .W = im.W
   .H = im.H
 End With
  
 PictureBox1.Picture = im.Picture
  
End


Public Sub Button1_Click()

 Dim st As Stream
 Dim b As Byte
 Dim j As Integer
 
' Viene dereferenziato il "Puntatore", mostrando così tutti i valori dei colori dei pixel della variabile immagine:
 st = Memory im.Data For Read Write
 
 Print "Dati dell'immagine originale:"
' La dimensione in byte effettiva di un'immagine si ottiene moltiplicando i pixel per la quantità di byte che compongono un singolo pixel (formato dei pixel).
 For j = 0 To (im.H * im.W * (im.Depth / 8)) - 1
   Read #st, b
   If j Mod (im.Depth \ 8) == 0 Then Print "------------------"
   Print j, Hex(b, 2)
 Next

 Print "\n------------------\nDati dell'immagine modificata:"

' Viene individuato il 2° pixel (si deve tenere bene in conto del formato dell'immagine !) per la mdifica del suo colore:
 Seek #st, 1 * (im.Depth / 8)
  
' Viene cambiato il colore del secondo pixel da giallo in rosso (se il formato è "diverso" dal "BGR", allora il primo byte a sinistra è relativo al valore "alfa" !):
 Write #st, &FFFF0000 As Integer
  
' Vengono nuovamente letti i valori dei colori dopo la modifica del 2° pixel:
 Seek #st, 0
 For j = 0 To (im.H * im.W * (im.Depth / 8)) - 1
   Read #st, b
   If j Mod (im.Depth \ 8) == 0 Then Print "------------------"
   Print j, Hex(b, 2)
 Next

 st.Close
 
' Mostra l'immagine come modificata:
 PictureBox1.Picture = im.Picture
 
End

Di seguito un altro esempio pratico, nel quale:

• sarà creato un Oggetto di tipo Image di dimensioni 3x3 pixel interamente di colore rosso;
• sarà modificato il pixel, che appare come centrale nell'immagine visiva, ossia il 5° pixel, assegnandogli la massima trasparenza (canale Alfa = &h00).

Public Sub Button1_Click()

 Dim im As Image
 Dim st As Stream
 
' Crea un Oggetto "Image" di dimensioni 3x3 pixel di colore rosso:
 im = New Image(3, 3, Color.Red, Image.Standard)
  
' Viene salvata questa "prima" versione dell'immagine creata, interamente colorata di rosso:
 im.Save("/tmp/prima_versione.png", 100)
  
' Con i "Memory Stream" accede alla memoria dell'Oggetto di tipo "image"' mediante la proprietà ".Data" della sua corrispondente variabile.
' In particolare la proprietà ".Data" dell'Oggetto "Image" è sostanzialmente un Puntatore, giacché essa restituisce l'indirizzo di memoria dell'area, ove tale Oggetto conserva i dati afferenti ai pixel dell'immagine.
 st = Memory im.Data For Write
  
' Individua il byte di memoria, ove hanno inizio i valori del pixel, al quale modificare i valori.
' Il byte di memoria va individuato tenendo conto del "formato" dell'immagine, ossia di quanti byte è formato un singolo pixel, moltiplicato per il numero indicizzato del pixel da modificare.
 Seek #st, (im.Depth / 8) * (im.Depth / 8)
  
' Scrive nella porzione, come sopra individuata, di memoria il nuovo valore del pixel interessato.
' Per attribuire la trasparenza, il byte (del pixel) corrispondente al canale "Alfa" dovrà essere impostato a zero.
 Write #st, 0 As Integer
 st.Close
  
' Salva l'immagine per andarla a vedere:
 im.Save("/tmp/immagine_con_pixel_centrale_trasparente.png", 100)

End

Note

[1] Vedi anche la pagina: Creare un'immagine senza avere un file immagine