Modificare i colori dei pixel di un'immagine con la proprietà .Data della Classe Image ed i Memory Stream

E' possibile modificare i colori dei pixel di un'immagine utilizzando la proprietà .Data della Classe Image ed i Memory Stream. ^{[nota 1]}

La proprietà .Data della Classe Image ritorna un Puntatore ai dati della variabile di tipo Image. Si potrà, quindi, per mezzo dei Memory Stream leggere all'interno dell'area puntata dal predetto Puntatore.
Sarà possibile altresì scrivervi modificando quindi il colore di uno o di più pixel dell'immagine.

Nell'esempio che segue abbiamo una semplice immagine formata da 2 x 2 pixel dei seguenti colori: rosso, verde, blu e giallo. Si procederà con il vedere quei quattro pixel ed a cambiare - subito dopo - il colore del pixel blu nel colore rosso:

Private im As Image


Public Sub Form_Open()
 
  im = Image.Load("/percorso/del/file/immagine")
  
  With PictureBox1
    .X = 50
    .Y = 50
    .W = im.W
    .H = im.H
  End With
  
  PictureBox1.Picture = im.Picture
  
End


Public Sub Button1_Click()

 Dim st As Stream
 Dim b As Byte
 Dim j As Integer
  
' Viene dereferenziato il "Puntatore", mostrando così tutti i valori dei colori dei pixel della variabile immagine:
  st = Memory im.Data For Read Write
 
  For j = 0 To (im.H * im.W * (im.Depth / 8)) - 1   ' La dimensione in byte effettiva di un'immagine si ottiene moltiplicando i pixel per la quantità di byte che compongono un singolo pixel (formato dei pixel)
    Read #st, b
    If j Mod (im.Depth \ 8) == 0 Then Print "------------------"
    Print j, Hex(b, 2)
  Next


  Print "\n------------------\nDati dell'immagine modificata"

' Viene modificato il colore del 4° pixel (si deve tenere bene in conto del formato dell'immagine !):
  Seek #st, 2 * (im.Depth / 8)
  
' Viene cambiato il colore blu nel colore rosso (se il formato è "diverso" dal "BGR", allora il primo byte a sinistra è relativo al valore "alfa" !):
  Write #st, &FFFF0000 As Integer
  
' Vengono nuovamente letti i valori dei colori dopo la modifica del terzo pixel:
  Seek #st, 0
  For j = 0 To (im.H * im.W * (im.Depth / 8)) - 1
    Read #st, b
    If j Mod (im.Depth \ 8) == 0 Then Print "------------------"
    Print j, Hex(b, 2)
  Next

  st.Close
 
' Mostra l'immagine come modificata:
  With PictureBox1
    .Stretch = True
    .W = .W * 8
    .H = .W * 8
    .Picture = im.Picture
  End With
 
End

Di seguito un altro esempio pratico, nel quale:

• sarà creato un Oggetto di tipo "Image" di dimensioni 3x3 pixel;
• l'immagine sarà colorata di rosso;
• sarà modificato il pixel, che appare come centrale nell'immagine visiva, ossia il 5° pixel, assegnandogli la massima trasparenza (canale Alfa = &h00).

E' necessario attivare anche i Componenti di Gambas gb.image e gb.image.io .

Public Sub Main()
 
 Dim im As Image
 Dim st As Stream
 
' Crea un Oggetto "Image" di dimensioni 3x3 pixel:
  im = New Image(3, 3)
  
' Colora l'intera immagine di rosso:
  im = im.Fill(Color.Red)
  
' Viene salvata questa "prima" versione dell'immagine creata, interamente colorata di rosso:
  im.Save("/tmp/prima.png", 100)
  
' Con i "Memory Stream" accede alla memoria dell'Oggetto di tipo "image"' mediante la proprietà ".Data" della sua corrispondente variabile.
' In particolare la proprietà ".Data" dell'Oggetto "Image" è sostanzialmente un Puntatore, giacché essa restituisce l'indirizzo di memoria dell'area,
' ove tale Oggetto conserva i dati afferenti ai pixel dell'immagine.
  st = Memory im.Data For Write
  
' Individua il byte di memoria, ove hanno inizio i valori del pixel, al quale modificare i valori.
' Il byte di memoria va individuato tenendo conto del "formato" dell'immagine, ossia di quanti byte è formato un singolo pixel, moltiplicato per il numero indicizzato del pixel da modificare.
  Seek #st, (im.Depth / 8) * (im.Depth / 8)
  
' Scrive nella porzione, come sopra individuata, di memoria il nuovo valore del pixel interessato.
' Per attribuire la trasparenza, il byte (del pixel) corrispondente al canale "Alfa" dovrà essere impostato a zero.
  Write #st, 0 As Integer
  st.Close
  
' Salva l'immagine per andarla a vedere:
  im.Save("/tmp/con_pixel_centrale_trasparente.png", 100)
  
End

Note

[1] Vedi anche la pagina: Creare un'immagine senza avere un file immagine