Ottenere un file Midi da un file XMI con le funzioni esterne del API di WildMidi
La libreria WildMidi consente attraverso l'uso della sua funzione "WildMidi_ConvertToMidi( )" di convertire un file XMI nei dati di un file MIDI.
In particolare detta funzione esterna elabora un file simil-MIDI (XMI) e cerca di rilevare, convertire e scrivere i dati in un buffer di memoria in formato MIDI.
Per poter fruire della risorsa WildMidi, è necessario avere installata nel sistema e richiamare in Gambas la libreria dinamica condivisa: "libWildMidi.so.2.0.1"
Poiché per inizializzare l'interfaccia di WildMidi è necessario richiamare un file (freepats.cfg oppure wildmidi.cfg) di configurazione dei campioni audio degli strumenti musicali, qualora non sia presente alcuno dei due file patch nel nostro sistema, ne verrà creato uno fittizio, primo di dati al suo interno. Sarà ugualmente accettato dalla funzione esterna WildMidi_Init(), alla quale dovrà essere passato nel suo secondo argomento.
Mostriamo un semplice esempio:
Library "libWildMidi:2.1.0"
Public Struct _WM_Info
copyright As Pointer
current_sample As Integer
approx_total_samples As Integer
mixer_options As Short
total_midi_time As Integer
End Struct
' WildMidi_Init (const char *config_file, unsigned short int rate, unsigned short int options)
' Intializes "libWildMidi" in preparation for playback.
Private Extern WildMidi_Init(config_file As String, rate As Short, options As Short) As Integer
' int WildMidi_ConvertToMidi(const char * file, uint8_t * * out, uint32_t * size)
' Convert a MIDI-like file into a new MIDI file.
Private Extern WildMidi_ConvertToMidi(__file As String, out As Pointer, size As Pointer) As Integer
' midi *WildMidi_Open (const char *midifile)
' Open a MIDI file pointed to by midifile for processing.
Private Extern WildMidi_Open(midifile As String) As Pointer
' struct _WM_Info * WildMidi_GetInfo (midi *handle)
' Get information on a midi.
Private Extern WildMidi_GetInfo(handle As Pointer) As _WM_Info
' int WildMidi_Close (midi *handle)
' Finish processing MIDI data or file.
Private Extern WildMidi_Close(handle As Pointer) As Integer
' void WildMidi_Shutdown(void)
' Shuts down the wildmidi library, resetting data and freeing up memory used by the library.
Private Extern WildMidi_Shutdown()
Public Sub Main()
Dim i, sz As Integer
Dim midi As Pointer
Dim xmi As String
Dim fl As File
Dim info As _WM_Info
' Crea un file fittizio di impostazione di campioni audio degli strumenti musicali, per poter inizializzare comunque la libreria "libWildMidi":
File.Save("/tmp/freepats.cfg", Null)
' Inizializza la libreria 'libWildMidi':
i = WildMidi_Init("/tmp/freepats.cfg", 44100, 0)
If i < 0 Then Error.Raise("Errore nell'inizializzazione dell'interfaccia 'libWildMidi' !")
' Alloca una porzione di memoria adeguata per contenere un file Midi:
midi = Alloc(SizeOf(gb.Byte), 500000)
' Carica un file XMI in memoria:
xmi = "/percorso/del/file.xmi"
' Converte i dati del file XMI nei dati di un file Midi:
i = WildMidi_ConvertToMidi(xmi, midi, VarPtr(sz))
If i < 0 Then Error.Raise("Errore")
' Mostra in console tutti i dati midi ricostruiti:
For i = 0 To sz - 1
Print i, Hex(Byte@(Pointer@(midi) + i), 2)
Next
Print
' Salva il file midi dai dati ottenuti:
fl = Open File.Dir(xmi) &/ File.BaseName(xmi) & ".mid" For Create
Write #fl, Pointer@(midi), sz
Free(midi)
' Apre il file Midi appena creato:
midi = WildMidi_Open(fl.Dir(xmi) &/ fl.Name(xmi))
If midi == 0 Then Error.Raise("Impossibile aprire il file Midi !")
' Ottiene alcune informazioni sul file Midi caricato:
info = WildMidi_GetInfo(midi)
Print "File Midi: "; fl.Dir(xmi) &/ fl.Name(xmi)
Print "Durata: "; "\e[31m"; Time(0, 0, 0, info.total_midi_time)
' Infine libera la memoria precedentemente occupata:
fl.Close
WildMidi_Close(midi)
WildMidi_Shutdown()
End
